循环遍历文件夹中的视频文件以获取视频长度

Question

我有以下内容,它返回所选视频文件的秒数.

然而,我想了一个方法,只是给它电影文件夹,然后循环遍历所有子目录,找到所有视频文件类型.

一旦它有这些我想列出"1小时53秒"类型格式的视频长度为"7990秒"是没有太大帮助.

谢谢

set macPath to (choose file) as text
tell application "System Events"
    set ts to time scale of movie file macPath
    set dur to duration of movie file macPath
    set movieTime to dur / ts
end tell

Answer 1

您的问题涉及几个子问题.

1)如何获取文件夹中的所有文件,包括子文件夹2)如何过滤该列表以仅包含视频文件3)如何遍历该视频文件列表并从每个文件中提取信息4 )如何将秒转换为可用的单词串

通常情况下,我会要求你将其分解为那些个别问题,因为有人为你写完整件事是一件大事.但是,在这种情况下,你很幸运,因为我在自己之前做过这个...所以你可以拥有我的剧本.我在代码中添加了很多注释,以帮助您了解它是如何工作的.

-- I found these extensions for video files here http://www.fileinfo.net/filetypes/video
-- we can check the file extensions of a file against this list to evaluate if it's a video file
set video_ext_list to {"3g2", "3gp", "3gp2", "3gpp", "3mm", "60d", "aep", "ajp", "amv", "asf", "asx", "avb", "avi", "avs", "bik", "bix", "box", "byu", "cvc", "dce", "dif", "dir", "divx", "dv", "dvr-ms", "dxr", "eye", "fcp", "flc", "fli", "flv", "flx", "gl", "grasp", "gvi", "gvp", "ifo", "imovieproject", "ivf", "ivs", "izz", "izzy", "lsf", "lsx", "m1v", "m2v", "m4e", "m4u", "m4v", "mjp", "mkv", "moov", "mov", "movie", "mp4", "mpe", "mpeg", "mpg", "mpv2", "msh", "mswmm", "mvb", "mvc", "nvc", "ogm", "omf", "prproj", "prx", "qt", "qtch", "rm", "rmvb", "rp", "rts", "sbk", "scm", "smil", "smv", "spl", "srt", "ssm", "svi", "swf", "swi", "tivo", "ts", "vdo", "vf", "vfw", "vid", "viewlet", "viv", "vivo", "vob", "vro", "wm", "wmd", "wmv", "wmx", "wvx", "yuv"}

-- get the folder to check
set f to choose folder

-- notice the use of "entire contents" to also go through subfolders of f
-- use a "whose" filter to find only the video files
tell application "Finder"
    set vidFiles to (files of entire contents of f whose name extension is in video_ext_list) as alias list
end tell

-- use a repeat loop to loop over a list of something
set vidList to {} -- this is where we store the information as we loop over the files
repeat with aFile in vidFiles
    -- get some information from aFile
    tell application "System Events"
        set vidFile to movie file (aFile as text)
        set ts to time scale of vidFile
        set dur to duration of vidFile
    end tell

    -- add the information to the "storage" list we made earlier
    set end of vidList to {POSIX path of aFile, secs_to_hms(dur / ts)}
end repeat

return vidList

(*=================== SUBROUTINES ===================*)
-- convert seconds into a string of words
-- the use of "mod" and "div" here makes it easy
-- we also make sure that each value is at least 2 places long to make it look nicer
on secs_to_hms(the_secs)
    set timeString to ""
    set hr to the_secs div hours
    if hr is not 0 then set timeString to timeString & (text -2 thru -1 of ("0" & (hr as text))) & " hours "

    set min to the_secs mod hours div minutes
    if min is not 0 then set timeString to timeString & (text -2 thru -1 of ("0" & (min as text))) & " minutes "

    set sec to the_secs mod minutes div 1
    if sec is not 0 then
        set fraction to text 2 thru 3 of ((100 + the_secs mod 1 * 100) as text)
        set timeString to timeString & (sec as text) & "." & fraction & " seconds"
    end if

    if timeString ends with space then set timeString to text 1 thru -2 of timeString
    return timeString
end secs_to_hms