如何生成不同频率的连续音？

Question

我希望生成并播放具有随时间变化的特定频率和幅度的连续声音.我不希望声音之间有延迟.如何使用Delphi或C++ Builder完成此操作？

Answer 1

这个非常简单的例子可以帮助你入门.

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows, MMSystem;

type
  TWaveformSample = integer; // signed 32-bit; -2147483648..2147483647
  TWaveformSamples = packed array of TWaveformSample; // one channel

var
  Samples: TWaveformSamples;
  fmt: TWaveFormatEx;

procedure InitAudioSys;
begin
  with fmt do
  begin
    wFormatTag := WAVE_FORMAT_PCM;
    nChannels := 1;
    nSamplesPerSec := 44100;
    wBitsPerSample := 32;
    nAvgBytesPerSec := nChannels * nSamplesPerSec * wBitsPerSample div 8;
    nBlockAlign := nChannels * wBitsPerSample div 8;
    cbSize := 0;
  end;
end;
                                          // Hz                     // msec
procedure CreatePureSineTone(const AFreq: integer; const ADuration: integer;
  const AVolume: double { in [0, 1] });
var
  i: Integer;
  omega,
  dt, t: double;
  vol: double;
begin
  omega := 2*Pi*AFreq;
  dt := 1/fmt.nSamplesPerSec;
  t := 0;
  vol := MaxInt * AVolume;
  SetLength(Samples, Round((ADuration / 1000) * fmt.nSamplesPerSec));
  for i := 0 to high(Samples) do
  begin
    Samples[i] := round(vol*sin(omega*t));
    t := t + dt;
  end;
end;

procedure PlaySound;
var
  wo: integer;
  hdr: TWaveHdr;
begin

  if Length(samples) = 0 then
  begin
    Writeln('Error: No audio has been created yet.');
    Exit;
  end;

  if waveOutOpen(@wo, WAVE_MAPPER, @fmt, 0, 0, CALLBACK_NULL) = MMSYSERR_NOERROR then
    try

      ZeroMemory(@hdr, sizeof(hdr));
      with hdr do
      begin
        lpData := @samples[0];
        dwBufferLength := fmt.nChannels * Length(Samples) * sizeof(TWaveformSample);
        dwFlags := 0;
      end;

      waveOutPrepareHeader(wo, @hdr, sizeof(hdr));
      waveOutWrite(wo, @hdr, sizeof(hdr));
      sleep(500);

      while waveOutUnprepareHeader(wo, @hdr, sizeof(hdr)) = WAVERR_STILLPLAYING do
        sleep(100);

    finally
      waveOutClose(wo);
    end;


end;


begin

  try
    InitAudioSys;
    CreatePureSineTone(400, 1000, 0.7);
    PlaySound;
  except
    on E: Exception do
    begin
      Writeln(E.Classname, ': ', E.Message);
      Readln;
    end;
  end;

end.

特别注意你得到的整洁界面:

    InitAudioSys;
    CreatePureSineTone(400, 1000, 0.7);
    PlaySound;

Answer 2

通过使用 WaveAudio 库，可以生成连续的余弦波。

我本来想发布一些代码，但我不知道如何正确地做到这一点，所以我不会。

但您需要做的就是使用 TLiveAudioPlayer，然后覆盖 OnData 事件。

如果没有消息泵，请将 Async 设置为 true。

• 2021 年 12 月更新，我只是偶然发现了我的答案...所以我想更新它，我认为我在 2009 年使用了这个 ASIO 库，后来，下面很棒的库：*

我会推荐 Delphi 的 ASIO 库！

https://sourceforge.net/projects/delphiasiovst/

使用它非常简单，不必包含所有文件，从主文件开始，然后从那里添加其余文件，另请参阅示例。

最终它就像 OnSomeEvent/OnSomeBuffer 一样简单

然后简单地用浮点值填充数组。

不记得 OnEvent 的确切名称，但您可以在示例中轻松找到它。

另一件要做的事情是将某些组件设置为 active/true ，瞧。

ASIO 的优点是延迟非常低，甚至可以降低到 50 微秒甚至更低。

它确实需要您的声音芯片的 ASIO 驱动程序。

ASIO = 音频流输入输出

API由音频工程师设计！

可能没有比这更好的了！;)