如何计算 COUNTIF 但仅计算唯一值？

Question

我有一个数据集，其中有一列包含参考文献。参考文献始终遵循相同的格式。“1-XXX-YYY”。XXX 始终为 3 个字母。YYY 始终是一个数字。每个XXX都会有YYY=001，如果同一个XXX有多个类型，就会有YYY=002等等。

我想知道每种类型有多少参考文献。但是，如果引用在文档中重复出现，则它只能算作 1。

我已经尝试过COUNTIF，但它显然不能正常工作。

正如您在示例中看到的，XYZ 引用被计为具有 2 个不同的条目。但实际上只有1-XYZ-001，而且出现了两次。

我应该使用什么公式才能使示例中的 XYZ 显示为 1，而其他公式则保持其值？

我已经看到了类似问题的解决方案，但在这个问题中，我的计数条件只是参考的一部分，我认为这会搞乱这样的事情。

Answer 1

如果字符串是唯一的，则计算子字符串的数量

编辑

• 我想在学习Excel之初的某个地方，人们学习了一个COUNT函数，即计算一个范围（数组）中的数字数量，但实际上不必使用=SUM(N(ISNUMBER(array)))（我在编辑之前使用过）。
• 可以简单地使用=COUNT(array).

单细胞配方（溢出）

=TOCOL(BYCOL(SEARCH(TOROW(C2:C4), UNIQUE(A2:A11)), LAMBDA(c, COUNT(c))))

D2（抄下）中的公式

=COUNT(SEARCH(C2, UNIQUE(A$2:A$11)))

Excel 表格计数列第一个单元格中的公式（向下溢出）

=COUNT(SEARCH([@Type], UNIQUE(Table1[Refs])))

Answer 2

另一种方法可能是：

=LET(a, A2:A8,
     m, UNIQUE(MID(a,3,3)),
     u, MID(UNIQUE(a),3,3),
HSTACK(m,
       MMULT(N(TOROW(u)=m),SEQUENCE(ROWS(u),,,0))))

或者如果你想按字母顺序排序：

=LET(a, A2:A8,
     m, SORT(UNIQUE(MID(a,3,3))),
     u, MID(UNIQUE(a),3,3),
HSTACK(m,
       MMULT(N(TOROW(u)=m),SEQUENCE(ROWS(u),,,0))))

或者按照Vbasic2008的建议，我们可以通过使用来提高效率：

=LET(a, A2:A8,
     u, MID(UNIQUE(a),3,3),
     m, SORT(UNIQUE(u)),
HSTACK(m,
       MMULT(N(TOROW(u)=m),SEQUENCE(ROWS(u),,,0))))