修复时密码查询警告给出不一致的结果

Question

当我运行此查询时：

MATCH (n:test) with n limit 100
WITH DISTINCT n, keys(n) AS allKeys
UNWIND allKeys AS key
with n, 
    CASE
        WHEN key STARTS WITH 'prop.title' THEN {column: 'title', value: collect(n[key])}
        WHEN key STARTS WITH 'prop.keywords' THEN {column: 'keywords', value: collect(n[key])}
    END AS data
with n, data, collect(data.value) as values
RETURN n.id, apoc.map.fromPairs(COLLECT([data.column, values]))

此查询的目的是查找具有给定前缀的所有属性，并将它们的值分组到带有 apoc 的对象中。示例结果如下所示：

当 Cypher 给我这个警告时，我的问题开始了：This feature is deprecated and will be removed in future versions.带有状态代码Neo.ClientNotification.Statement.FeatureDeprecationWarning 然后我尝试通过将 the 添加key到WITH关键字来修复查询，如下所示：WITH n, key, CASE ... 但现在我的对象 ( ) 中的值collect(n[key])不再返回所有值，而只返回最后一个值。我想其余的都被覆盖了。

有谁知道如何解决这个问题但仍删除警告？

编辑：我发现通过在第一个查询中更改n为而不添加，我得到了相同的错误结果。还添加图片。*key

Answer 1

我相信您可以将查询重写为如下所示：

MATCH (n:test) with n limit 100 
WITH DISTINCT n, keys(n) AS allKeys
UNWIND allKeys AS key
WITH n, 
    // Note: in the original query you used the aggregation expression `collect` which made `key` an implicit grouping key.
    CASE
      WHEN key STARTS WITH 'prop.title' THEN {column: 'title', value:n[key]}
      WHEN key STARTS WITH 'prop.keywords' THEN {column: 'keywords', value:n[key]}
    END AS data
WITH n, data.column AS column, collect(data.value) as values
RETURN n.id, apoc.map.fromPairs(COLLECT([column, values]))

原始查询的问题是您在聚合表达式之外使用了非分组键，即所谓的“隐式分组键”。在 neo4j 5.0 之前，我们允许隐式分组键，但由于这可能会变得非常混乱，因此在 5.0 中被删除了。您可以在此处阅读有关隐式分组键的混淆的更多信息：https://opencypher.org/articles/2017/07/27/ocig1-aggregations-article/

那么，让我们一步一步来：

假设您有一个节点：

CREATE (:test{`prop.title1`:"title1", `prop.title2`:"title2", `prop.keywords`:"hey!"})

在这部分查询之后：

MATCH (n:test) with n limit 100
WITH DISTINCT n, keys(n) AS allKeys
UNWIND allKeys AS key

你有：

n	钥匙	所有键
n	“prop.title1”	[“prop.title1”，“prop.title2”，“prop.keywords”]
n	“prop.title2”	[“prop.title1”，“prop.title2”，“prop.keywords”]
n	“prop.keywords”	[“prop.title1”，“prop.title2”，“prop.keywords”]`

让我们看一下原始查询的下一部分：

with n, 
CASE
    WHEN key STARTS WITH 'prop.title' THEN {column: 'title', value: collect(n[key])}
    WHEN key STARTS WITH 'prop.keywords' THEN {column: 'keywords', value: collect(n[key])}
END AS data

显式分组键是不包含任何聚合的投影变量/属性 - 在本例中为n. 这意味着在聚合表达式之外使用的所有其他变量都是“隐式”分组键 - 在您的情况下，隐式分组键是key。从 5.0 开始不再支持隐式分组键。但是，您可以删除聚合表达式“collect”，而不是将其添加为显式分组键：

WITH n, 
     CASE
       WHEN key STARTS WITH 'prop.title' THEN {column: 'title', value:n[key]}
       WHEN key STARTS WITH 'prop.keywords' THEN {column: 'keywords', value:n[key]}
     END AS data

这意味着我们知道：

n	数据
n	{列：“标题”，值：“标题1”}
n	{列：“标题”，值：“标题2”}
n	{列：“关键字”，值：“嘿！”}`

如果您现在查看原始查询的下一部分：

with n, data, collect(data.value) as values

collect您再次拥有带有分组键n和 的聚合表达式data。但您不想对整个data对象进行分组，而是希望收集所有data.values按n和分组的对象data.column：

WITH n, data.column AS column, collect(data.value) as values

这给了我们：

n	柱子	价值观
n	“标题”	[“标题1”，“标题2”]
n	“关键词”	[“嘿！”]

我希望这能让它更清楚一些