Android 找不到 androidx.compose.ui:ui-test-junit4

Question

我在尝试运行 Compose UI 测试时收到此错误

Could not find androidx.compose.ui:ui-test-junit4:.
Required by:
    project :app
Search in build.gradle files

还有谁有相同的问题吗 ？

我已将此行放入依赖项中

androidTestImplementation "androidx.compose.ui:ui-test-junit4"

编辑：

/*
 * Copyright 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
}

android {
    compileSdk 33

    defaultConfig {
        applicationId "com.example.reply"
        minSdk 21
        targetSdk 33
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables {
            useSupportLibrary true
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }
    buildFeatures {
        compose true
    }
    composeOptions {
        kotlinCompilerExtensionVersion '1.3.0'
    }
    packagingOptions {
        resources {
            excludes += '/META-INF/{AL2.0,LGPL2.1}'
        }
    }
}

dependencies {
    implementation platform('androidx.compose:compose-bom:2023.01.00')
    implementation 'androidx.activity:activity-compose:1.6.1'
    implementation 'androidx.core:core-ktx:1.9.0'
    implementation "androidx.compose.ui:ui"
    implementation "androidx.compose.material3:material3"
    implementation "androidx.compose.material3:material3-window-size-class:$material3_version"
    implementation "androidx.compose.material:material-icons-extended"
    implementation "androidx.compose.ui:ui-tooling-preview"
    implementation "androidx.lifecycle:lifecycle-viewmodel-compose:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-runtime-ktx:$lifecycle_version"
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    androidTestImplementation "androidx.compose.ui:ui-test-junit4"
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    debugImplementation("androidx.compose.ui:ui-test-manifest")
    debugImplementation "androidx.compose.ui:ui-tooling"
}

Answer 1

如果您还添加以下行，它就会起作用：

androidTestImplementation platform('androidx.compose:compose-bom:2023.01.00')

Answer 2

在行末尾添加依赖版本号：

androidTestImplementation "androidx.compose.ui:ui-test-junit4:1.4.1"