ANTLR @header,@ parser,superClass选项和基本文件io(Java)

Question

我想在基本文件io(Java)中使用解析器操作,例如在ANTLR语法中使用PrintWriter.我必须使用superClass选项还是可以使用@header？在这两种情况下,我如何声明PrintWriter对象以及如何处理异常？

Answer 1

该选项superClass=...用于Parser扩展自定义类.所以,我不认为这就是你所追求的.

该@header部分内的所有内容都将放在课程开始时Parser.这用于导入类:

@header {
  import java.io.PrintWriter;
}

请注意,这@header {...}是简称@parser::header {...}.您还可@lexer::header {...}以为您的词法分析器定义:

在内部@member {...}(或:@parser::member {...},@lexer::member {...})部分中,您可以添加可在Parser或中使用的实例变量和方法Lexer:

@header {
  import java.io.PrintWriter;
}

@members {
  PrintWriter writer;
}

一个语法的小型演示,其解析器将解析的数字写入特定的编写器:

grammar T;

@header {
  import java.io.PrintWriter;
}

@members {
  PrintWriter writer;

  public TParser(TokenStream input, String fileName) {
    super(input);
    try {
      writer = new PrintWriter(fileName);
    } catch(Exception e) {
      e.printStackTrace();
    }
  }
}

parse
  :  numbers EOF
  ;

numbers
  :  (NUM {
            writer.println("parsed: " + $NUM.text);
            writer.flush();
          }
     )+
  ;

NUM : '0'..'9'+;
WS  : ' ' {skip();};

可以测试:

import java.io.File;
import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    String source = "42 500000000 666";
    TLexer lexer = new TLexer(new ANTLRStringStream(source));
    TParser parser = new TParser(new CommonTokenStream(lexer), "log.txt");
    parser.parse();
  }
}

如果您运行上面的类,log.txt则创建一个名为的文件,其中包含:

parsed: 42
parsed: 500000000
parsed: 666

请注意,是所有这些严格的秩序@...和options {...}等实例:

1. grammar 定义
2. options块(没有@迹象!)
3. tokens块(没有@迹象!)
4. @header 块
5. @members 块

grammar T;

options {
  // options here
}

tokens {
  // imaginary tokens here
}

@header  { 
  // ... 
}

@members { 
  // ... 
}

编辑

ANTLRStarter写道:

如何添加在词法分析器/解析器类末尾执行的代码？

这种东西没有内置功能.但您可以wrapUp()在解析器中轻松创建自定义方法:

@members {

  // ...

  private void wrapUp() {
    // wrap up your parser in here
  }
}

然后从语法的入口点自动调用该方法,如下所示:

parse
@after {this.wrapUp();}
  :  numbers EOF
  ;

@after {...}当规则中的所有内容都正确匹配时,将执行放置在规则块中的任何代码.