我如何知道我的存储过程是否在MS SQL Server中被删除？

Question

它有时会发生,我怎么知道我的存储过程何时在我不知情的情况下被删除/删除？

每当我调试并发现知道存储过程没有退出时,它会让我很烦,这是几天前创建和测试的.

有没有办法知道MS SQL Server中删除的存储过程？

Answer 1

检查程序是否存在的标准方法是

if exists(
    SELECT * FROM INFORMATION_SCHEMA.ROUTINES
    WHERE routine_type = N'PROCEDURE' and routine_name = @procname)
  print 'exists'

从MSSQL 2005开始,您可以使用[DDL trigger](http://msdn.microsoft.com/en-us/library/ms190989 ( SQL.90%29.aspx)在删除或创建过程时发送电子邮件通知:

USE msdb
GO
CREATE TABLE ddl_log
(ID int idenity(1,1) PRIMARY KEY CLUSTERED,
 PostTime datetime,
 DB_User nvarchar(100),
 Event nvarchar(100),
 TSQL nvarchar(2000));

CREATE TRIGGER DDL_Notify
ON DATABASE
FOR DROP_PROCEDURE, CREATE_PROCEDURE
AS
DECLARE @data XML,
        @tableHTML  NVARCHAR(MAX) ;

SET @data = EVENTDATA()

INSERT msdb.dbo.ddl_log (PostTime, DB_User, Event, TSQL)
VALUES (GETDATE(), CONVERT(nvarchar(100), USER_NAME()),
   @data.value('(/EVENT_INSTANCE/EventType)[1]', 'nvarchar(100)'),
   @data.value('(/EVENT_INSTANCE/TSQLCommand)[1]', 'nvarchar(2000)') ) ;

SET @tableHTML =
    N'<H1>DDL Table Event</H1>' +
    N'<table border="1">' +
    N'<tr><th>Post Time</th><th>User</th>' +
    N'<th>TSQL</th><th></tr>' +
    CAST ( ( SELECT td = PostTime, '',
                    td = DB_User, '',
                    td = TSQL, ''
              FROM msdb.dbo.ddl_log
              WHERE id = (select max(id) from msdb.dbo.ddl_log)
              FOR XML PATH('tr'), TYPE
    ) AS NVARCHAR(MAX) ) +
    N'</table>';

EXEC msdb.dbo.sp_send_dbmail
    @profile_name = 'Default',
    @recipients = 'dba@youraddress.com',
    @subject = 'DDL Table Event',
    @body = @tableHTML,
    @body_format = 'HTML'