CMake&CTest:make test不构建测试

Question

我在CMake中尝试CTest,以便使用make testtarget 自动运行我的一些测试.问题是CMake没有"理解"我愿意运行的测试必须构建,因为它是项目的一部分.

所以我正在寻找一种明确指定这种依赖关系的方法.

Answer 1

它可以说是CMake中的一个错误(此前已在此处跟踪过),这不是开箱即用的.解决方法是执行以下操作:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

然后你可以运行make check它将编译并运行测试.如果你有几个测试,那么你必须DEPENDS exe1 exe2 exe3 ...在上面的行中使用.

Answer 2

实际上有一种使用方法make test.您需要将测试可执行文件的构建定义为其中一个测试,然后在测试之间添加依赖项.那是:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Answer 3

我使用了richq的答案变体.在顶层CMakeLists.txt,我添加了一个自定义目标build_and_test,用于构建和运行所有测试:

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

在下面的各个子项目CMakeLists.txt文件中test/,我将每个测试可执行文件添加为依赖项build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

使用这种方法,我只需要make build_and_test代替make test(或make all test),它只有构建测试代码(及其依赖项)的好处.遗憾的是我无法使用目标名称test.在我的情况下,它并没有那么糟糕,因为我有一个顶级脚本,通过调用cmake然后进行树外调试和发布(和交叉编译)构建make,并转换test为build_and_test.

显然,GTest的东西不是必需的.我碰巧使用/喜欢Google Test,并希望分享一个与CMake/CTest一起使用它的完整示例.恕我直言,这种方法也有允许我使用的好处ctest -V,它在测试运行时显示Google Test输出:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Answer 4

如果您使用 CMake >= 3.7，那么推荐的方法是使用fixtures：

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

这将执行以下操作：

• 添加test从构建的可执行目标test.cpp
• 添加test_build运行 Cmake 以构建目标的“测试”test
• 将test_build测试标记为夹具的设置任务test_fixture
• 添加一个test只运行test可执行文件的测试
• 标记test测试需要fixture test_fixture。

因此，每次test运行 test 时test_build，它首先运行 test ，它构建必要的可执行文件。

Answer 5

如果您尝试模拟make check,您可能会发现此Wiki条目有用:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

我刚刚检查过它是否成功(CMake 2.8.10).

Answer 6

免得自己头疼：

make all test

对我来说开箱即用，并将在运行测试之前构建依赖项。鉴于这是多么简单，它几乎使本机make test功能变得方便，因为即使您的代码被破坏，它也为您提供了运行最后编译测试的选项。