AS3如何检查BitmapData是否为空

Question

我有一个代码来擦除蒙面动画片段.(在这里学分)我想知道如何检查整个动画片段是否已被删除.所以我认为我必须检查BitmapData是否为空,但我可能非常错!如何检查动画片段的每个像素是否已被删除？
当然我的下面的例子是错误的,但我认为它必须是这样的.

if (erasableBitmapData = empty)
    { 
    trace("empty")
    }

---

    var lineSize:Number=40;
    var doDraw:Boolean=false;
    var resumeDrawing:Boolean=false;

    var erasableBitmapData:BitmapData = new BitmapData(700, 500, true, 0xFFFFFFFF);
    var erasableBitmap:Bitmap = new Bitmap(erasableBitmapData);
    erasableBitmap.cacheAsBitmap = true;
    addChild(erasableBitmap);

    maskee.cacheAsBitmap = true;
    maskee.mask = erasableBitmap;

    var eraserClip:Sprite = new Sprite();
    initEraser();
    function initEraser():void {
        eraserClip.graphics.lineStyle(lineSize,0xff0000);
        eraserClip.graphics.moveTo(stage.mouseX,stage.mouseY);
    }

    var drawnBitmapData:BitmapData = new BitmapData(700, 500, true, 0x00000000);
    var drawnBitmap:Bitmap = new Bitmap(drawnBitmapData);

    stage.addEventListener(MouseEvent.MOUSE_MOVE,maskMove);
    stage.addEventListener(MouseEvent.ROLL_OUT, maskOut); 
    stage.addEventListener(MouseEvent.ROLL_OVER,maskOver);
    stage.addEventListener(MouseEvent.MOUSE_DOWN,startDrawing);
    stage.addEventListener(MouseEvent.MOUSE_UP,stopDrawing);

    function startDrawing(e:MouseEvent):void {
        eraserClip.graphics.moveTo(stage.mouseX,stage.mouseY);
        doDraw=true;
    }

    function stopDrawing(e:MouseEvent):void {
        doDraw=false;
        resumeDrawing = false;
    }

    function maskOut(e:Event):void {
        if (doDraw){
            resumeDrawing = true;
        }
    }

    function maskOver(e:MouseEvent):void {
        if (resumeDrawing){
            resumeDrawing = false;
            eraserClip.graphics.moveTo(stage.mouseX,stage.mouseY);
        }
    }

    function maskMove(e:MouseEvent):void {
        if (doDraw && !resumeDrawing){
            eraserClip.graphics.lineTo(stage.mouseX,stage.mouseY);
            drawnBitmapData.fillRect(drawnBitmapData.rect, 0x00000000); 
            drawnBitmapData.draw(eraserClip , new Matrix(), null, BlendMode.NORMAL);
            erasableBitmapData.fillRect(erasableBitmapData.rect, 0xFFFFFFFF);
            erasableBitmapData.draw(drawnBitmap, new Matrix(), null, BlendMode.ERASE);
        }
            e.updateAfterEvent();
    }


    reset_btn.addEventListener(MouseEvent.CLICK,reset);

    function reset(e:Event):void {
        eraserClip.graphics.clear();
        initEraser();
        erasableBitmapData.fillRect(erasableBitmapData.rect, 0xFFFFFFFF);
    }

Answer 1

您可以检查是否getColorBoundsRect返回一个矩形,其宽度和高度0为您认为为"空"的颜色,将findColor参数设置为false.还有其他方法可以做到这一点,但这比检查每个像素要快很多倍.

参数的默认值true为findColor您提供了一个矩形,其中包含所有像素,这些(pixelColor & mask) == emptyColor是真的.处理alpha值时,0xFF000000可以使用掩码来忽略像素的rbg值并仅检查其alpha值.因此,蒙版0xFF000000和颜色0xFF000000将匹配所有完全不透明的像素,而蒙版0xFF000000和颜色0x00000000将匹配所有完全透明的像素.正如meddlingwithfire指出的那样,这不会在这里完成任务.通过设置findColor为false,此过程是相反的,以便矩形将包含所有不使用空颜色的像素.对于不包含其他颜色的位图,结果将是面积为的矩形0.

var maskColor:uint = 0xFF000000;
var emptyColor:uint = 0x00000000;
var bounds:Rectangle = erasableBitmapData.getColorBoundsRect(maskColor, emptyColor, false);
if (bounds.width == 0 && bounds.height == 0){
    trace("empty"); // no visible pixels
}

从技术上讲,黑色透明像素0x00000000和红色透明像素之间0x00FF0000存在差异 - 但没有可见的差异(两者都是不可见的),因此您应该完全忽略rgb值,就像我在示例中使用该特定蒙版所做的那样.