在clojure中修改Clojure源代码文件

Question

我想知道是否可以将Clojure .clj源文件中包含的代码作为列表加载,而无需编译它.

如果我可以将.clj文件作为列表加载,我可以修改该列表并将其打印回相同的文件,然后可以再次加载.

(也许这是一个坏主意.)有谁知道这是否可能？

Answer 1

这不是一个坏主意,它是lisp的主要属性之一,代码就是数据.您可以使用读取字符串将clj文件作为列表读取并将其写回.

(ns tmp
  (:require [clojure.zip :as zip])
  (:use clojure.contrib.pprint))

(def some-var true)

;;stolen from http://nakkaya.com/2011/06/29/ferret-an-experimental-clojure-compiler/
(defn morph-form [tree pred f]
  (loop [loc (zip/seq-zip tree)]
    (if (zip/end? loc)
      (zip/root loc)
      (recur
       (zip/next
        (if (pred (zip/node loc))
          (zip/replace loc (f (zip/node loc)))
          loc))))))

(let [morphed (morph-form (read-string (str \( (slurp "test.clj")\)))
                          #(or (= 'true %)
                               (= 'false %))
                          (fn [v] (if (= 'true v)
                                   'false
                                   'true)))]
  (spit "test.clj"
        (with-out-str
          (doseq [f morphed]
            (pprint f)))))

这会读取自身并切换布尔值并将其写回.

Answer 2

一个稍微简单一点的例子：

user=> (def a '(println (+ 1 1))) ; "'" escapes the form to prevent immediate evaluation
#'user/a
user=> (spit "test.code" a) ; write it to a file
nil

user=> (def from-file (read-string (slurp "test.code"))) ; read it from a file
#'user/from-file
user=> (def modified (clojure.walk/postwalk-replace {1 2} from-file)) ; modify the code
#'user/modified
user=> (spit "new.code" modified) ; write it back
nil
user=> (load-string (slurp "new.code")) ; check it worked!
4
nil

whereslurp给你一个字符串，read-string给你一个未评估的形式，并load-string给你评估该形式的结果。