为什么时间需要是一个宏？

Question

Clojure源代码给出了以下定义time

(defmacro time
  "Evaluates expr and prints the time it took.  Returns the value of
 expr."
  {:added "1.0"}
  [expr]
  `(let [start# (. System (nanoTime))
         ret# ~expr]
     (prn (str "Elapsed time: " (/ (double (- (. System (nanoTime)) start#)) 1000000.0) " msecs"))
     ret#))

为什么这需要一个宏？函数无法完成怎么办？

Answer 1

因为函数在开始使用参数之前会对其参数进行求值。您可以编写time为函数并尝试调用它：

(defn my-time [expr]
  (let [start (System/nanoTime)
        ret expr]
    (prn (str "Elapsed time: " (/ (double (- (System/nanoTime) start)) 1000000.0) " msecs"))
    ret))

(my-time (Thread/sleep 1000))
"Elapsed time: 0.005199 msecs"
=> nil

与宏比较time：

(time (Thread/sleep 1000))
"Elapsed time: 1000.1222 msecs"
=> nil

函数my-time计算了 argument (Thread/sleep 1000)，符号expr得到了值nil，然后该函数的主体发生了——两个函数(System/nanoTime)很快就被调用了，因为 的值expr已经计算出来了。

宏time没有计算(Thread/sleep 1000)，但扩展为：

(macroexpand `(time (Thread/sleep 1000)))
=>
(let*
 [start__6136__auto__ (. java.lang.System (clojure.core/nanoTime)) ret__6137__auto__ (java.lang.Thread/sleep 1000)]
 (clojure.core/prn
  (clojure.core/str
   "Elapsed time: "
   (clojure.core//
    (clojure.core/double (clojure.core/- (. java.lang.System (clojure.core/nanoTime)) start__6136__auto__))
    1000000.0)
   " msecs"))
 ret__6137__auto__)

和函数按以下顺序调用：(System/nanoTime)和(Thread/sleep 1000)other (System/nanoTime)，它返回正确的时间。