如何在MS Word中使用VBA选择文档中的所有数学方程？

Question

我对 MS Word 中的 VBA 编辑器相当陌生，我想知道是否有一种方法可以使用 VBA 选择 Word 文档中的所有数学方程？例如下面的代码

Sub Change_Equation_Color()
Dim Eq As OMath
For Each Eq In ActiveDocument.OMaths
Eq.Range.Select
Selection.Font.ColorIndex = wdDarkBlue '
Next
End Sub

按顺序选择每个数学方程并将每个方程的颜色更改为“wdDarkBlue”。即使这很好，有没有办法首先选择所有方程，然后更改选择的颜色/字体/等？主要原因是，如果我的文档有很多方程，那么提供的代码会有点慢，因为它必须按顺序遍历每个方程。

编辑。@Timothy Rylatt 提供了一个非常快速且通用的方法，但出于我的目的，我发现以下代码实际上要快得多。

Sub Eq2LM()
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Format = False
        .Font.Name = "Cambria Math"
        .Text = ""
       
        With .Replacement
            .ClearFormatting
            .Font.Name = "Latin Modern Math"
            .Text = ""
        End With
        .Execute Forward:=True, Replace:=wdReplaceAll
    End With
End Sub

“警告”是，您的方程必须全部采用“Cambria math”字体，这通常是默认字体。

Answer 1

无法使用 VBA 创建不连续的选择。

Selection尽管偶尔有必要使用该对象，但这并不是一个好的做法。通常有更好的替代方案，它们更有效且更不易出错。例如：

Sub Change_Equation_Color()
    Dim Eq As OMath
    Application.ScreenUpdating = False
    For Each Eq In ActiveDocument.OMaths
        Eq.Range.Font.ColorIndex = wdDarkBlue
    Next
    Application.ScreenUpdating = True
End Sub