Backbone.js的表单生成器插件？

Question

是否有任何Backbone.js插件可以执行"form_for"为Rails做什么？例如,我提供了一个模型,它提供了一个用于构建表单的DSL？

Answer 1

我认为这是一个不同的野兽，有不同的解决方案。我编写了一个backbone.js 扩展，用于将表单元素绑定到Backbone.Model 字段。请原谅咖啡脚本，但我通常会执行以下操作。

class FooView extends MyView

  tag: "div"

  modelBindings:

    "change form input.address" : "address"
    "change form input.name"    : "name"
    "change form input.email"   : "email"

  render: ->

    $(@el).html """
      <form>
        <input class="address"/>
        <input class="name"/>
        <input class="email"/>
      </form>
    """

    super

    @


# Instantiate the view 
view = new FooView
  model: new Backbone.Model

$("body").html(view.el) 

绑定代码的实现是

class MyView extends Backbone.View

  render: ->

    if @model != null
      # Iterate through all bindings
      for selector, field of @modelBindings
        do (selector, field) =>
          console.log "binding #{selector} to #{field}"
          # When the model changes update the form
          # elements
          @model.bind "change:#{field}", (model, val)=>
            console.log "model[#{field}] => #{selector}"
            @$(selector).val(val)

          # When the form changes update the model
          [event, selector...] = selector.split(" ")
          selector = selector.join(" ")
          @$(selector).bind event, (ev)=>
            console.log "form[#{selector}] => #{field}"
            data = {}
            data[field] = @$(ev.target).val()
            @model.set data

          # Set the initial value of the form
          # elements
          @$(selector).val(@model.get(field))

    super

    @

我在这里写了一篇关于此的小博客文章。

http://xtargets.com/2011/06/11/binding-model-attributes-to-form-elements-with-backbone-js/