Kotlin 中的奇怪值比较问题，“===”返回 true 但“==”返回 false

Question

我在Kotlin中遇到了一个很奇怪的值比较问题，无法解释，下面代码打印false

data class Foo (
    val a: Byte
)
fun main() {
    val NUM: Byte = 1
    var m: Foo? = Foo(NUM)
    println(m?.a == NUM)
}

但是如果我将最后一行更改为

println(m?.a === NUM)

或者

println(m!!.a == NUM)

它打印为true，我很困惑，有人可以帮忙解释一下吗？谢谢。

Answer 1

该问题仅出现在 1.5.20 版本中，而 1.5.10 不受影响。

这似乎是较新的 kotlin 编译器版本中的一个问题。

用一些字节码我们可以解释这个问题（data class被调用Blah，func被调用blah）。

这是字节码，用1.5.10编译的，这回报True了println(m?.a == NUM)-似乎一切都很好。我们正在做一个原始的不等于两个数字，它返回False（正确，因为1 != 1是False）。

Compiled from "WtfTest.kt"
public final class de.sfxr.WtfTest {
  public de.sfxr.WtfTest();
    Code:
       0: aload_0
       1: invokespecial #8                  // Method java/lang/Object."<init>":()V
       4: return

  public final void blah();
    Code:
       0: iconst_1
       1: istore_1
       2: new           #14                 // class de/sfxr/Blah
       5: dup
       6: iload_1
       7: invokespecial #17                 // Method de/sfxr/Blah."<init>":(B)V
      10: astore_2
      11: aload_2
      12: astore_3
      13: aload_3
      14: invokevirtual #21                 // Method de/sfxr/Blah.getA:()B
      17: iload_1
      18: istore_3
      19: iload_3
      // PRIMITIVE NOT EQUALS => False
      20: if_icmpne     27                  
      23: iconst_1
      24: goto          28
      27: iconst_0
      28: istore_3
      29: iconst_0
      30: istore        4
      32: getstatic     #27                 // Field java/lang/System.out:Ljava/io/PrintStream;
      35: iload_3
      36: invokevirtual #33                 // Method java/io/PrintStream.println:(Z)V
      39: return
}

然而，在1.5.20版本，字节码指令使用的JVM的对象比较Intrinsics.areEqual上一盒装Integer的内容1和盒装Byte的内容1，这将返回False，因为它使用equals上Byte。这是这个问题的根本原因。编译器开发人员此时肯定想要一个True。

但为什么这评估为假？这Byte.equals是描述的片段“当且仅当参数不为空并且是包含与此对象相同的字节值的 Byte 对象时，结果才为真。”

...以及用于解释的字节码：

Compiled from "WtfTest.kt"
public final class de.sfxr.WtfTest {
  public de.sfxr.WtfTest();
    Code:
       0: aload_0
       1: invokespecial #8                  // Method java/lang/Object."<init>":()V
       4: return

  public final void blah();
    Code:
       0: iconst_1
       1: istore_1
       2: new           #14                 // class de/sfxr/Blah
       5: dup
       6: iload_1
       7: invokespecial #17                 // Method de/sfxr/Blah."<init>":(B)V
      10: astore_2
      11: aload_2
      12: astore_3
      13: aload_3
      14: invokevirtual #21                 // Method de/sfxr/Blah.getA:()B
      17: invokestatic  #27                 // Method java/lang/Byte.valueOf:(B)Ljava/lang/Byte;
      20: iload_1
      21: invokestatic  #32                 // Method java/lang/Integer.valueOf:(I)Ljava/lang/Integer;
      // OBJECT COMPARISON VIA JVM ON BOXED BYTE(1) AND BOXED INT(1) => False
      24: invokestatic  #38                 // Method kotlin/jvm/internal/Intrinsics.areEqual:(Ljava/lang/Object;Ljava/lang/Object;)Z    
      27: istore_3
      28: iconst_0
      29: istore        4
      31: getstatic     #44                 // Field java/lang/System.out:Ljava/io/PrintStream;
      34: iload_3
      35: invokevirtual #50                 // Method java/io/PrintStream.println:(Z)V
      38: return
}

更新

来自 jetbrains 的人对已发出的票https://youtrack.jetbrains.com/issue/KT-47717发表评论说： “这绝对是一个错误。” 和优先专业。

恭喜，你找到了一些东西:-)