如何使用 Perl IPC::Run3 从子进程中读取 stdout 和 stderr？

Question

我想make从 Perl 脚本运行一个命令，以便我可以捕获它的 stdout 和 stderr 流。我知道我可以使用，open(MAKE, "make 2>&1 |")但这会给构建正确的 shell 命令以将参数传递给make，并且使用open(MAKE, "-|", @makecmd, "2>&1")不起作用，因为将命令作为数组传递不会产生子shell 来执行重定向。

我遇到了IPC::Run3并且我已经让它工作了，但是我对文件句柄的使用很丑 - 基本上我不得不产生一个cat子进程来获得一个我可以告诉我IPC::Run3写的句柄，这样我的脚本就可以从中读取，而我STDIN为此目的而通过的尝试失败了。我究竟做错了什么？

#!/usr/bin/perl

use strict;
use warnings;
use IPC::Run3;

#my $pipe = \*STDIN;           #-- this produces no output and hangs
#open(my $pipe, "<&STDIN");    #-- this outputs "foo bar" and hangs
open(my $pipe, "|cat");        #-- this works, but extra process is ugly

run3 "echo foo; echo bar >&2", \undef, $pipe, $pipe;

while (<$pipe>) {
    print ">>> $_";
}

Answer 1

你没有。您可以改用 IPC::Run。天真地使用 IPC::Open3 会让你容易陷入死锁。避免这种情况涉及使用 IO::Select 或其他一些机制。涉及的工作是广泛的。IPC::Open3 对于实际使用来说太低级了。

也就是说，您只处理一个文件句柄。这可以相对简单地使用open3.

use IPC::Open3 qw( open3 );

open(local *CHILD_STDIN, '<', '/dev/null') or die $!;
*CHILD_STDIN if 0;
pipe(local (*READER, *WRITER)) or die $!;
my $pid = open3('<&CHILD_STDIN', '>&WRITER', '>&WRITER', @cmd);

close(WRITER);

while (<READER>) {
   ...
}

waitpid($pid);

糟糕！使用 IPC::Run 更干净。

use IPC::Run qw( run );

run \@cmd, \undef, '>pipe', \my $pipe, '2>&1';

while (<$pipe>) {
   ...
}

close($pipe);

嗯，这就是文档所说的，但它不起作用。你实际上需要

use IPC::Run qw( run );
use Symbol   qw( gensym );

run \@cmd, \undef, '>pipe', (my $pipe = gensym), '2>&1';

while (<$pipe>) {
   ...
}

close($pipe);

如果你想要所有的输出，你可以简单地使用

use IPC::Run qw( run );

run \@cmd, \undef, \my $output;

最后，您提到了构建 shell 命令的问题。

你要找的是

use String::ShellQuote qw( shell_quote );

my $cmd = shell_quote(@cmd) . ' 2>&1';
open(my $pipe, '-|', $cmd);

while (<$pipe>) {
   ...
}

close($pipe);