在vb6中使用RegEx

Question

我需要验证一个字符串,它可能包含字母数字和特殊字符,因为我必须传递只有Alpha字符的字符串(不允许使用数字或任何其他特殊字符)

在当前的方法中,我使用ASCII数字来评估每个字符是否为alpha.有没有其他有效的方法来发现字符串中是否存在特殊字符或数字？就像我们不能使用Like或者其他东西来检查一次而不是逐个字符？

For y = 2 To Len(sString)
    If Not ((Asc(Mid$((sString,y,1))>64 AND Asc(Mid$((sString,y,1))<91) OR _
    (Asc(Mid$((sString,y,1))>96 AND Asc(Mid$((sString,y,1))<123)) Then
        //Display an error msg
        Exit For
    End If
Next y

Answer 1

您可以在VB6中使用正则表达式.您必须在项目中添加对"Microsoft VBScript Regular Expressions 5.5"库的引用.然后,您可以使用以下内容:

Dim rex As RegExp
Set rex = New RegExp
rex.Pattern = "[^a-zA-Z]"
If rex.Test(s) Then
    ' Display error message
End If

当我最初回答这个问题时,它被标记为VB.NET; 为了将来参考,我的原始.Net答案保留在下面

如你所想,这可以用正则表达式完成(不要忘记Imports System.Text.RegularExpressions:

If Regex.IsMatch(s, "[^a-zA-Z]") Then
    ' Display error msg
End If

此外,原始代码读取像VB6代码,而不是VB.NET.这是一种更可读的方式来编写原始的非正则表达式代码:

For Each ch As Char In someString
    If Not (ch >= "a"c AndAlso ch <= "z"c OrElse ch >= "A"c AndAlso ch <= "Z"c) Then
        ' Display error msg
        Exit For
    End If
Next

Answer 2

VBA有一个本机Like运算符:它的语法是非标准的,例如它的多字符通配符*和NOT运算符是!:

If sString Like "*[!A-Za-z]*" Then
  ' Display an error msg
End If

Answer 3

您必须添加对Microsoft VBScript Regular Expressions 5.5

检查非字母字符的代码：

'Prepare a regular expression object
Dim myRegExp As RegExp
Dim myMatches As MatchCollection
Dim myMatch As Match
Dim matchesFound As Boolean

Set myRegExp = New RegExp
myRegExp.IgnoreCase = True
myRegExp.Global = True
myRegExp.Pattern = "[^A-Za-z]+"
Set myMatches = myRegExp.Execute("abc123def#$%")
matchesFound = myMatches.Count > 0

有关详细信息，请参阅Microsoft 支持的如何在 Microsoft Visual Basic 6.0 中使用正则表达式。