动态 SQL 存储过程和日期时间

Question

我有一个简单的查询，我想将其转换为动态 SQL。我有 2 个输入参数：一个表和一个日期时间。输出是表的行计数和这个特定的日期时间。

CREATE PROCEDURE [etl].[ROWCOUNT_TST2]
    (@P_LOAD_TARGET nvarchar(250),
     @P_LOAD_DATE DATETIME)
AS
BEGIN
    DECLARE @SQL nvarchar(1000)

    SET @SQL = 'SELECT COUNT(*) as Inserted FROM'+@P_LOAD_TARGET +' WHERE VALID_FROM ='''+  @P_LOAD_DATE+''' AND VALID_TO IS NULL'

    EXEC  (@SQL)
END;
GO

我尝试了不同的解决方案。我尝试使用execute进行查询sp_executesql，我在.之前和之后添加了''' @P_LOAD_DATE。我可能在这里遗漏了一些东西。

当我使用表名和日期时间执行存储过程（如 ）时2021-05-06 06:41:52.557，出现以下错误：

从字符串转换日期和/或时间时转换失败。

但为什么？

我什至尝试像这样添加到日期时间的转换，但我仍然遇到相同的错误。

 SET @SQL = 'SELECT COUNT(*) as Inserted FROM'+@P_LOAD_TARGET +' WHERE VALID_FROM = convert(datetime,'''+  @P_LOAD_DATE+''') AND VALID_TO IS NULL'

但是当我执行 SELECT Convert(datetime, '2021-05-06 06:41:52.557') 时效果很好。我现在很困惑，找不到问题的根源。

编辑：valid_from是目标表中的日期时间。所以这也不是问题的原因

Answer 1

您需要正确且安全地注入动态对象名称并参数化您的参数：

CREATE PROCEDURE [etl].[ROWCOUNT_TST2](@P_LOAD_SCHEMA sysname = N'dbo', --Always define your schema
                                       @P_LOAD_TARGET sysname, --sysname is the data type for objects, a synonym of nvarchar(128) NOT NULL
                                       @P_LOAD_DATE datetime) AS
BEGIN

    DECLARE @SQL nvarchar(MAX),
            @CRLF nchar(2) = NCHAR(13) + NCHAR(10);

    SET @SQL = N'SELECT COUNT(*) AS Inserted' + @CRLF +
               N'FROM ' + QUOTENAME(@P_LOAD_SCHEMA) + N'.' + QUOTENAME(@P_LOAD_TARGET) + @CRLF +
               N'WHERE VALID_FROM = @P_LOAD_DATE' + @CRLF +
               N'  AND VALID_TO IS NULL;';

    --PRINT @SQL; --Your best friend.
    EXEC sys.sp_executesql @SQL, N'@P_LOAD_DATE datetime', @P_LOAD_DATE;

END;