类型类与函数？

Question

我目前正在尝试使用 typeclasses & 作为练习，能够登录各种上下文（即在 IO 上下文中打印到控制台）。我首先将我的Logger实现为一个由各种用于日志记录的函数组成的类型类，我的想法是我可以为 IO monad 定义一个实例，但为其他 monad 的上下文中的其他实现留出空间。

最终结果是：

-- |Class / wrapper for convenient use within another monad.
class Logger m where
    -- |Logs an error message /(prefixed with the '__[ERROR]__' tag)/
    logError    :: String -> m ()
 
    -- |Logs a warning message /(prefixed with the '__[WARNING]__' tag)/
    logWarning  :: String -> m ()

    -- |Logs a success message /(prefixed with the '__[SUCCESS]__' tag)/
    logSuccess  :: String -> m ()

    -- |Logs an informative message /(prefixed with the '__[INFO]__' tag)/
    logInfo     :: String -> m ()

    -- |Logs a regular message /(i.e with no prefix)/
    logMsg      :: String -> m ()

-- |Instance of logger in the IO monad
instance Logger IO where
    logError    = printError
    logWarning  = printWarning
    logSuccess  = printSuccess
    logInfo     = printInfo
    logMsg      = printMsg

-- |Instance of logger for a state
instance (MonadIO m) => Logger (StateT s m) where
    logError    = liftIO . printError
    logWarning  = liftIO . printWarning
    logSuccess  = liftIO . printSuccess
    logInfo     = liftIO . printInfo
    logMsg      = liftIO . printMsg

这在当时似乎是个好主意（并且来自 OOP 背景，当我可能不应该将所有东西都变成“类”时，我被吸引了）

我开始意识到我可以直接使用类型约束轻松定义我的日志记录函数并称之为一天，例如：

logError :: (MonadIO m) => String -> m ()
logError = liftIO . printError

对于其他函数，依此类推，我会有一些可以在任何基于 IO 的 monad 中调用的东西......

---

显然，这两种解决方案各有利弊。

我的Logger类型类用例是否可以被视为“滥用”，或者我是否有正确的想法以这种方式实现它（我的理解是类型类允许临时多态性，这正是我想到的）。

我已经读过 & 我仍然试图完全概念化的一个限制是，对于任何给定的类型只能有一个类型类的实例，所以在我的情况下，我已经为StateT定义了一个实例，它位于IO 中monad，这意味着我无法覆盖具有相同签名的后续状态。我知道这个警告，但我很难想到这会成为一个具体问题的情况。

另一方面，简单的基于函数的方法使用起来同样优雅​​，尽管它确实防止在没有定义要在不同上下文中使用的全新函数的情况下覆盖行为。

当函数可以轻松完成工作时，类型类是否应该仅作为最后的手段使用/编写？

我将不胜感激对这两种方法的一些见解和反馈。

提前致谢，

Answer 1

绝对重用已经完成你关心的事情的类型类——在这种情况下，MonadIO.

也就是说，我认为日志记录是一个特别有趣的应用程序。例如，考虑AccumT [String] IO. 日志应该提升IO操作，还是add？一个明显正确而另一个明显不正确并不是很清楚。出于这个原因，您甚至可以考虑从 typeclass 路由——每个类型只能有一个实现——到 ADT 路由：

-- incidentally, you should use this in your class, too
data Level = Error | Warning | Success | Info | Msg
    deriving (Eq, Ord, Read, Show, Bounded, Enum)

newtype Logger m = Logger { log :: Level -> String -> m () }

然后你可以有单独的实现AccumT：

makeLoggingMessage :: Level -> String -> String
makeLoggingMessage lev msg = show lev ++ ": " ++ msg -- or whatever

viaIO :: MonadIO m => Logger m
viaIO = Logger $ \lev msg -> liftIO . putStrLn $ makeLoggingMessage lev msg

viaAccum :: Monad m => Logger (AccumT [String] m)
viaAccum = Logger $ \lev msg -> add [makeLoggingMessage lev msg]

也可能有其他变体；例如，可能一个添加时间戳，一个不添加时间戳。

顺便说一下，这种数据类型建议不仅仅是学术性的。lumberjack库的LogAction数据类型¹几乎就是这样，围绕它构建了一个完整的库，并且被专业的 Haskell 程序员使用。

在三个选项（现有类型类、新类型类或数据类型）之间进行选择，您会慢慢获得经验。根据经验，关于这个主题，我能给新人的最可靠的建议可能是：不要创建新的类型类。^_^

¹有些人可能也从co-log库中认识到了这一点，我听说这是伐木工人设计中的一个重要灵感。