那些遇到过的问题

将多个 XSLT 文件转换为用于 2 个不同 xml 文件的单个 XSLT 文件

lin*_*ini 3 xml eclipse xslt

这是我的 xml 文件：

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>
    <CONTACT>
        <FirstName>Ford</FirstName>
        <LastName>Pasteur</LastName>
        <EMail>pasteur.ford@yahoo.com</EMail>
    </CONTACT>
    <CONTACT>
        <FirstName>Jack</FirstName>
        <LastName>Sully</LastName>
        <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    </CONTACT>
    <CONTACT>
        <FirstName>Colombo</FirstName>
        <LastName>Chao</LastName>
        <EMail>chao.colombo@liberto.it</EMail>
    </CONTACT>
</CONTACTS>
Run Code Online (Sandbox Code Playgroud)

我在第一个版本的 xml 输出中使用了下面的 XSLT 文件。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="CONTACT">
        <xsl:copy>
               <Customer-ID>
               <xsl:value-of select="generate-id(.)"/> 
               </Customer-ID>
              <xsl:copy-of select="FirstName|LastName|URL"/>
              <Facebook-ID>
            <xsl:choose>
                <xsl:when test="URL">
                    <xsl:value-of select="substring-after(URL,'?id=')"/>
                </xsl:when>
                <xsl:otherwise>

                </xsl:otherwise>
            </xsl:choose>
        </Facebook-ID>
            <EMAILS>
                <xsl:apply-templates select="EMail"/>
            </EMAILS>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="EMail">
        <EMail> 
            <Type><xsl:value-of select="substring-before(
                    substring-after(.,'@'),
                    '.')"/>
            </Type>
            <Value><xsl:value-of select="."/></Value>
        </EMail>
    </xsl:template>

</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

我从上述 XSLT 文件输出的第一个 xml 版本：

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>
    <CONTACT>
    <Customer-ID>N65539</Customer-ID>
    <FirstName>Ford</FirstName>
    <LastName>Pasteur</LastName>
    <EMAILS>
    <EMail>
    <Type>yahoo</Type>
    <Value>pasteur.ford@yahoo.com</Value>
    </EMail>
    </EMAILS>
    </CONTACT>
    <CONTACT>
    <Customer-ID>N65546</Customer-ID>
     <FirstName>Jack</FirstName>
     <LastName>Sully</LastName>
     <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    <Facebook-ID>1000474277</Facebook-ID>
    <EMAILS/>
    </CONTACT>
    <CONTACT>
    <Customer-ID>N65553</Customer-ID>
    <FirstName>Colombo</FirstName>
    <LastName>Chao</LastName>
    <EMAILS>
    <EMail>
    <Type>liberto</Type>
    <Value>chao.colombo@liberto.it</Value>
    </EMail>
    </EMAILS>
    </CONTACT>
</CONTACTS>
Run Code Online (Sandbox Code Playgroud)

这是我的第二个 XSLT 文件：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="CONTACT">
<xsl:copy>
    <Customer-ID>
        <xsl:value-of select="Customer-ID"/>
    </Customer-ID>

    <FirstName>
        <xsl:value-of select="FirstName"/>
    </FirstName>

    <LastName>
        <xsl:value-of select="LastName"/>
    </LastName>

    <gmail>
            <xsl:value-of select="EMAILS/EMail[Type='gmail']/Value"/>
    </gmail>

    <yahoo>
            <xsl:value-of select="EMAILS/EMail[Type='yahoo']/Value"/>
    </yahoo>

    <liberto>
            <xsl:value-of select="EMAILS/EMail[Type='liberto']/Value"/>
    </liberto>

    <URL>
            <xsl:value-of select="URL"/>
    </URL>

    <Facebook-ID>
             <xsl:value-of select="Facebook-ID"/>
    </Facebook-ID>

      </xsl:copy>
</xsl:template>
Run Code Online (Sandbox Code Playgroud)

这是我来自第二个 XSLT 文件的最终 xml 输出：

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>

    <CONTACT>
    <Customer-ID>N65539</Customer-ID>
    <FirstName>Ford</FirstName>
    <LastName>Pasteur</LastName>
    <gmail/>
    <yahoo>pasteur.ford@yahoo.com</yahoo>
    <liberto/>
    <URL/>
    <Facebook-ID/>
    </CONTACT>

    <CONTACT>
    <Customer-ID>N65546</Customer-ID>
    <FirstName>Jack</FirstName>
    <LastName>Sully</LastName>
    <gmail/>
    <yahoo/>
    <liberto/>
    <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    <Facebook-ID>1000474277</Facebook-ID>
    </CONTACT>

    <CONTACT>
    <Customer-ID>N65553</Customer-ID>
    <FirstName>Colombo</FirstName>
    <LastName>Chao</LastName>
    <gmail/>
    <yahoo/>
    <liberto>chao.colombo@liberto.it</liberto>
    <URL/>
    <Facebook-ID/>
    </CONTACT>
</CONTACTS>
Run Code Online (Sandbox Code Playgroud)

如何将这两个 XSLT 文件合并为一个 XSLT 文件以获得最终的 XML 输出。

我该如何处理？因为有两个类似类型的不同 xml 文件。

我正在使用 Eclipse Hellios run as -->XSL 转换来查看输出。

Dim*_*hev 5

执行转换链在 XSLT 应用程序中经常使用，尽管在 XSLT 1.0 中完全执行此操作需要使用特定于供应商的xxx:node-set()功能。在 XSLT 2.0 中不需要这样的扩展，因为那里消除了臭名昭著的 RTF 数据类型。

这是一个示例（太简单而没有意义，但完全说明了这是如何完成的）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
   <xsl:variable name="vrtfPass1">
    <xsl:apply-templates select="/*/*"/>
   </xsl:variable>

   <xsl:variable name="vPass1"
        select="ext:node-set($vrtfPass1)"/>

   <xsl:apply-templates mode="pass2"
        select="$vPass1/*"/>
 </xsl:template>

 <xsl:template match="num[. mod 2 = 1]">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="num" mode="pass2">
  <xsl:copy>
    <xsl:value-of select=". *2"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

当此转换应用于以下 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>
Run Code Online (Sandbox Code Playgroud)

产生了想要的、正确的结果：

<num>2</num>
<num>6</num>
<num>10</num>
<num>14</num>
<num>18</num>
Run Code Online (Sandbox Code Playgroud)

说明：

  1. 在第一步中，XML 文档被转换，结果被定义为变量的值$vrtfPass1。这仅复制num具有奇数值（不是偶数）的元素。

  2. $vrtfPass1RTF 类型的变量不能直接用于 XPath 表达式，因此我们将其转换为普通树，使用 EXSLT（由大多数 XSLT 1.0 处理器实现）函数ext:node-set并定义另一个变量 ——$vPass1其值就是这棵树。

  3. 我们现在执行转换链中的第二个转换——基于第一个转换的结果，即作为变量的值$vPass1。为了不弄乱第一遍模板，我们指定新处理应处于命名模式，称为“pass2”。在这种模式下，任何num元素的值都乘以 2。

XSLT 2.0 解决方案（无 RTF）：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vPass1" >
   <xsl:apply-templates select="/*/*"/>
  </xsl:variable>
   <xsl:apply-templates mode="pass2"
        select="$vPass1/*"/>
 </xsl:template>

 <xsl:template match="num[. mod 2 = 1]">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="num" mode="pass2">
  <xsl:copy>
    <xsl:value-of select=". *2"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>
Run Code Online (Sandbox Code Playgroud)

归档时间：

查看次数：

2379 次

最近记录：

14 年，4 月 前
相关归档
xdebug不会在断点处停止 23
如何在eclipse IDE中查看Java的字节码？ 21
在Eclipse中运行JUnit单元测试时使用ClassNotFoundException(使用Maven) 17
Lombok和STS问题 - 方法未定义 9
还原后,在自定义ContentProvider中刷新/重新加载数据库引用 8
如何为所有行选择XML字段节点 8
XmlSerializer构造函数错误,类派生自基类 7
JQuery mobile - > .append()删除CSS？ 7
xsl中的撇号文本比较 5
如何在F#上创建XNamespace？ 5
难疑归档
如何克隆特定的Git分支？ 2804
Vim清除上次搜索突出显示 1824
NPM vs. Bower vs. Browserify vs. Gulp vs. Grunt vs. Webpack 1811
如何在Node.js中退出 1762
配置错误:此配置部分不能在此路径中使用 1694
如何获取所有Git分支 1371
将零填充到字符串的最好方法 1309
检查值是否是JavaScript中的对象 1194
.NET - 枚举的jSON序列化为字符串 1088
iOS 6上的Safari缓存$ .ajax结果吗？ 1057