GDI+ DrawLine 什么也不画

Question

开始在 Delphi 中使用 GDI+。需要画几条平滑的直线。例如，试图在表单上绘制对角线（从左上角到右下角），但什么也没出现。该代码有什么问题（Delphi XE3，Windows 10 x64）？

unit Unit2;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Winapi.GDIPAPI, Winapi.GDIPOBJ;

type
  TForm2 = class(TForm)
    procedure FormPaint(Sender: TObject);
    procedure FormResize(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.FormPaint(Sender: TObject);
var
  graphics: TGPGraphics;
  gpPen: TGPPen;
begin
  graphics := TGPGraphics.Create(Self.Canvas.Handle);
  try
    graphics.SetSmoothingMode(SmoothingModeAntiAlias8x8);
    gpPen := TGPPen.Create(clBlue, 3);
    try
      graphics.DrawLine(gpPen, 0, 0, ClientWidth, ClientHeight);
    finally
      gpPen.Free;
    end;
  finally
    graphics.Free;
  end;
end;

procedure TForm2.FormResize(Sender: TObject);
begin
  Repaint;
end;

end.

Answer 1

问题是颜色。

这是一种 GDI+颜色，它与TColor本质上是 Win32 的 a 不同COLORREF。

你通过了clBlue = $00FF0000，现在被（错误地）解释为 (alpha, red, green, blue) = ($00, $FF, $00, $00)。由于 alpha 值为 0，因此线条完全透明。

如果你这样做

gpPen := TGPPen.Create(clBlue or $FF000000, 3);

相反，您将获得完全不透明度。但是你会得到红色，而不是蓝色，因为TColoris$00BBGGRR而不是$00RRGGBB。所以如果你这样做

gpPen := TGPPen.Create($FF0000FF, 3);

你得到你想要的蓝色。

也许更好的是使用该MakeColor功能：

gpPen := TGPPen.Create(MakeColor(0, 0, $FF), 3)

或者ColorRefToARGB：

gpPen := TGPPen.Create(ColorRefToARGB(clBlue), 3)