如何将 Arduino 的模拟输入读数从 sketch 转换为 .WAV

Question

我正在尝试用 arduino 构建一个录音机。现在，该设置有一个麦克风，记录输入并输出到 Arduino uno 的模拟输入。

如何将（时间戳、数据）读数转换为 .WAV？我知道有更多的库可以做到这一点，但我试图了解 .WAV 的结构，并希望能够在 C\C++ 中自己编写脚本。

感谢您的关注！

Answer 1

第一步：定义 wav header 变量

/// The first 4 byte of a wav file should be the characters "RIFF" */
char chunkID[4] = {'R', 'I', 'F', 'F'};
/// 36 + SubChunk2Size
uint32_t chunkSize = 36; // You Don't know this until you write your data but at a minimum it is 36 for an empty file
/// "should be characters "WAVE"
char format[4] = {'W', 'A', 'V', 'E'};
/// " This should be the letters "fmt ", note the space character
char subChunk1ID[4] = {'f', 'm', 't', ' '};
///: For PCM == 16, since audioFormat == uint16_t
uint32_t subChunk1Size = 16;
///: For PCM this is 1, other values indicate compression
uint16_t audioFormat = 1;
///: Mono = 1, Stereo = 2, etc.
uint16_t numChannels = 1;
///: Sample Rate of file
uint32_t sampleRate = 44100;
///: SampleRate * NumChannels * BitsPerSample/8
uint32_t byteRate = 44100 * 2;
///: The number of byte for one frame NumChannels * BitsPerSample/8
uint16_t blockAlign = 2;
///: 8 bits = 8, 16 bits = 16
uint16_t bitsPerSample = 16;
///: Contains the letters "data"
char subChunk2ID[4] = {'d', 'a', 't', 'a'};
///: == NumSamples * NumChannels * BitsPerSample/8  i.e. number of byte in the data.
uint32_t subChunk2Size = 0; // You Don't know this until you write your data

这里做了一些假设，例如音频质量。以上假设 CD 品质音频 16 位、44.1kHz。如果您需要其他内容，则需要修改相关值。

您还需要了解您的 Arduino 是否确实定期记录样本，或者这是否本质上是数据的声音化。

步骤 2：打开 Wav 文件。

#include <SPI.h>
#include <SD.h>

File wavFile;
const char* filename = "data.wav";


void setup()
{

  Serial.begin(9600);
  while (!Serial);

  if (!SD.begin(4))
    while (1);

  wavFile = SD.open(filename, FILE_WRITE);


  if (!wavFile)
    while (1);


}

步骤 3：将标头写入 Wav 文件。

考虑到SD 库的组织方式，如果标题中的元素byte尚未存在，则必须将它们强制转换为char。Have to可能有点强，但它确实可以更轻松地维护标头每个元素的正确字节宽度，而不会做太多的事情。

将其包装在它自己的函数中是有意义的。

void writeWavHeader()
{
   wavFile.write(chunkID,4);
   wavFile.write((byte*)&chunkSize,4);
   wavFile.write(format,4);
   wavFile.write(subChunk1ID,4);
   wavFile.write((byte*)&subChunk1Size,4);
   wavFile.write((byte*)&audioFormat,2);
   wavFile.write((byte*)&numChannels,2);
   wavFile.write((byte*)&sampleRate,4);
   wavFile.write((byte*)&byteRate,4);
   wavFile.write((byte*)&blockAlign,2);
   wavFile.write((byte*)&bitsPerSample,2);
   wavFile.write(subChunk2ID,4);
   wavFile.write((byte*)&subChunk2Size,4);
}

第 4 步：将数据添加到 Wav 文件

wav 标头告诉我们 chunkSize 和 subChunk2Size 取决于文件中的数据量。因此，如果您将数据附加到文件中，这些数据将会增长并且必须进行更改。

有几种方法可以添加数据

• 一次添加一个样品
• 添加固定大小的数据缓冲区
• 存储所有数据并将其全部添加到最后

您选择什么方法将取决于您的实现，我们对此没有太多信息。为了便于讨论，我们一次写一个示例。这种方法应该展示所需的内容，并且缺点（定期在文件中跳转、大量重复）应该立即显而易见。

void writeDataToWavFile(int data)
{
  int16_t sampleValue = map(data, MIN_DATA_VALUE, MAX_DATA_VALUE,-32767,32767);

  subChunk2Size += numChannels * bitsPerSample/8;
  wavFile.seek(40);
  wavFile.write((byte*)&subChunk2Size,4);

  wavFile.seek(4);
  chunkSize = 36 + subChunk2Size;
  wavFile.write((byte*)&chunkSize,4);

  wavFile.seek(wavFile.size()-1);
  wavFile.write((byte*)&sampleValue,2);
}

MIN_DATA_VALUE并且MAX_DATA_VALUE是您必须定义的东西。这一切都假设您正在使用整数数据。如果是浮点数，则需要进行一些调整。

共。

#include <SPI.h>
#include <SD.h>

int MIN_DATA_VALUE;
int MAX_DATA_VALUE;
File wavFile;
const char* filename = "data.wav";

/// The first 4 byte of a wav file should be the characters "RIFF" */
char chunkID[4] = {'R', 'I', 'F', 'F'};
/// 36 + SubChunk2Size
uint32_t chunkSize = 36; // You Don't know this until you write your data but at a minimum it is 36 for an empty file
/// "should be characters "WAVE"
char format[4] = {'W', 'A', 'V', 'E'};
/// " This should be the letters "fmt ", note the space character
char subChunk1ID[4] = {'f', 'm', 't', ' '};
///: For PCM == 16, since audioFormat == uint16_t
uint32_t subChunk1Size = 16;
///: For PCM this is 1, other values indicate compression
uint16_t audioFormat = 1;
///: Mono = 1, Stereo = 2, etc.
uint16_t numChannels = 1;
///: Sample Rate of file
uint32_t sampleRate = 44100;
///: SampleRate * NumChannels * BitsPerSample/8
uint32_t byteRate = 44100 * 2;
///: The number of byte for one frame NumChannels * BitsPerSample/8
uint16_t blockAlign = 2;
///: 8 bits = 8, 16 bits = 16
uint16_t bitsPerSample = 16;
///: Contains the letters "data"
char subChunk2ID[4] = {'d', 'a', 't', 'a'};
///: == NumSamples * NumChannels * BitsPerSample/8  i.e. number of byte in the data.
uint32_t subChunk2Size = 0; // You Don't know this until you write your data



void setup()
{

  Serial.begin(9600);
  while (!Serial);

  if (!SD.begin(4))
    while (1);

  wavFile = SD.open(filename, FILE_WRITE);


  if (!wavFile)
    while (1);

  writeWavHeader();

}

void loop()
{
  int data = getSomeData();
  writeDataToWavFile(data);
}

void writeWavHeader()
{
   wavFile.seek(0);
   wavFile.write(chunkID,4);
   wavFile.write((byte*)&chunkSize,4);
   wavFile.write(format,4);
   wavFile.write(subChunk1ID,4);
   wavFile.write((byte*)&subChunk1Size,4);
   wavFile.write((byte*)&audioFormat,2);
   wavFile.write((byte*)&numChannels,2);
   wavFile.write((byte*)&sampleRate,4);
   wavFile.write((byte*)&byteRate,4);
   wavFile.write((byte*)&blockAlign,2);
   wavFile.write((byte*)&bitsPerSample,2);
   wavFile.write(subChunk2ID,4);
   wavFile.write((byte*)&subChunk2Size,4);
}


void writeDataToWavFile(int data)
{
  int16_t sampleValue = map(data, MIN_DATA_VALUE, MAX_DATA_VALUE,-32767,32767);

  subChunk2Size += numChannels * bitsPerSample/8;
  wavFile.seek(40);
  wavFile.write((byte*)&subChunk2Size,4);

  wavFile.seek(4);
  chunkSize = 36 + subChunk2Size;
  wavFile.write((byte*)&chunkSize,4);

  wavFile.seek(wavFile.size()-1);
  wavFile.write((byte*)&sampleValue,2);
}

总共

• 您需要知道数据的最小值/最大值或限制它们。
• 您必须确保定期进行录制，否则您将得到伪影。