Delphi：从二进制表示中定义 const double

Question

背景

我想创建一个单元测试来测试 Delphi 的一些 rtl 方面，为了做到这一点，我想使用我想直接从二进制表示创建的非常具体的 IEEE 浮点值。

到目前为止，我已经提出了这个例程，它实际上完成了这项工作。

function TestIEEEDouble.BuildDoubleFromRawInt64(const aBinData:UInt64):double;
begin
  CheckEquals(sizeof(aBinData),sizeof(Result),'sizeof(aBinData),Sizeof(Result)'); // ensures we dont mess up with wrong types
  Move(aBinData,Result,sizeof(Result));
end;

它的用法如下（bindata 可能仍然是错误的，但这不是问题）：

procedure TestIEEEDouble.Setup;
begin
  inherited;
  FSmallestPositiveDouble:=BuildDoubleFromRawInt64($0000000000000001);
  FSmallestNegativeDouble:=BuildDoubleFromRawInt64($8000000000000001);
  FLargestPositiveDouble :=BuildDoubleFromRawInt64($7FEFFFFFFFFFFFFF);
  FLargestNegativeDouble :=BuildDoubleFromRawInt64($8FEFFFFFFFFFFFFF);
end;

题

是否有允许const double直接从二进制（十六进制）表示创建一个看起来像这样的语法：

const
  cSmallestPositiveDouble:double=double($0000000000000001);

结果显然不应该是1.0（使用这种语法）但是（接近）4.94065645841247e-324

Answer 1

这可以直接通过工会完成：

type  // In a union all variables share the same address
  TAll= packed record
    case Integer of
    1:( d: Double );
    2:( i: Int64 );
    3:( f: TFileTime );
  end;

const  // Define the constant just like you would define an array
  ALL: TAll= ( i: 43 );

其余的很明显：要么您现在访问ALL.d，看看43asInt64是如何解释为Double. 或者反过来做。同样，您甚至可以TFileTime通过访问ALL.f.

在处理或检查二进制文件时，请记住字节顺序也很重要（LE 与 BE）——尤其是从不同的存储类型（FS 与 RAM）读取时。

Answer 2

用我自己的初始解决方案来回答，语法比我喜欢的要广泛一些，但这似乎可以使用变体记录和隐式类型转换来解决问题。

不错的功能/副作用是您可以在检查器/观察窗口中快速看到二进制表示和双重表示。

type
  RDoubleHelperRec=record
    class operator Implicit(aRec:RDoubleHelperRec):double;
    case Bin:boolean of
      True:
        (BinData:UINT64);
      False:
        (DoubleData:double);
  end;
...
class operator RDoubleHelperRec.Implicit(aRec: RDoubleHelperRec): double;
begin
  Result:=aRec.DoubleData;
end;

然后在使用时声明为const：

procedure TestIEEEDouble.TestCompareValueBoundary;
const
  cSmallestPositiveDouble:RDoubleHelperRec=(BinData:$0000000000000001);
begin
  CheckEquals(0,CompareValue(FSmallestPositiveDouble,cSmallestPositiveDouble),'CompareValue(FSmallestPositiveDouble,cSmallestPositiveDouble)');
end;