Ada 通用链表和通用包访问

Question

我试图在 Ada 中从通用 Node 类中构建通用链表。但是，尽管使用了with子句和相应的前缀，但我无法访问链接列表中节点的类型和形式参数。

genericnode.ads：

generic
   type item_type is private;

package GenericNode is
   type Node is limited private;
   type NodePtr is access Node;
   
   procedure GetData(n : in Node; e : out item_type);
   procedure GetNext(n : in Node; x : out NodePtr);
   
   procedure SetData(n : in out Node; e : in item_type);
   procedure SetNext(n : in out Node; x : in NodePtr);
   
private
   type Node is
      record
         data : item_type;
         next : NodePtr;
      end record;

end GenericNode;

genericsll.ads：

with GenericNode;

generic
   size : Positive;
   type node_type is private;
package GenericSLL is
   
   type SLL is limited private;
   
   procedure Append(s : in out SLL; d : in GenericNode.item_type);
   
   procedure PrintTraversal(s : in SLL);
   
private
   type SLL is
      record
         head : NodePtr := null;
         length : Positive := 0;
      end record;

end GenericSLL;

在编译时，我被告知Invalid prefix in selected component "GenericNode"和"NodePtr" is not visible有关genericsll.ads。有什么建议？谢谢！

Answer 1

对于 Ada 中的通用包，您需要先实例化它们。GenericNode 不是一个包；它是包的配方，给定类型 item_type。这两个错误都表明存在此问题；编译器正确地声明没有这样的包，也没有这样的类型 NodePtr。（“所选组件 GenericNode 中的前缀无效”只是意味着我不知道您所说的“GenericNode”是什么意思）

在 C++ 中，您可能确实希望在节点类型上参数化您的单链表，然后告诉编译器“只需获取此节点类型的 X 和 Y 成员，即使我没有告诉您节点类型是什么实际上是没有'，Ada 编译器拒绝这样做，因为它会导致容易出错的代码，您无法确定类型应该满足什么（C++20 中的合同旨在修补这个问题）。

艾达不允许这样做；每个包都必须在使用前实例化，以便知道每个类型的参数。不幸的是，这也意味着在 Ada 中不可能像在 C++ 中那样进行任意的编译时计算。

如果您在 item_type 而非 node_type 上参数化 GenericSLL，它可以使用该 item_type 实例化它需要的特定 GenericNode 包。只需要修改GenericSLL：

with GenericNode;

generic
   size : Positive;
   type item_type is private;
package GenericSLL is

   package LinkedList_Node is new GenericNode(item_type);
   use LinkedList_Node;

   type SLL is limited private;
   
   procedure Append(s : in out SLL; d : in item_type);
   
   procedure PrintTraversal(s : in SLL);
   
private
   type SLL is
      record
         head : NodePtr := null;
         length : Natural := 0; -- Positive starts at 1
      end record;

end GenericSLL;