terraform覆盖子模块中的标签值

Question

我正在使用 terraform 模块并将一组 default_tags 传递给子模块以实现一致的标记。如下所示，其优点是子模块继承其父模块的标签，但也可以添加自己的标签。

然而，我还想做的是能够覆盖一些继承的标签值，特别是“名称”。但我似乎无法完成这项工作。

在下面的示例中（带有 AWS 的 terraform 13.5），为任何标签指定的第一个值（例如根模块中的“scratch-test”）会向下级联到子模块，并且无法更改。因此，VPC 名称标签和子网名称标签均 =“scratch-test”。

如何覆盖子模块中的标签值？

# root variables.tf
variable "default_tags" {
    type = map
    default = {
        environment_type = "Dev Environment"
    }
} 


# root main.tf
provider "aws" {
    region = var.region
}

module "vpc" {
    source = "../../../../scratch/tags-pattern"
    vpc_name                = "scratch-test"
    public_subnets          = ["10.0.0.0/26"]

    default_tags = merge(map(
        "Name", "scratch-test"
    ), var.default_tags)
}

# ../../../../scratch/tags-pattern/main.tf
module "the_vpc" {
    source = "../../terraform/tf-lib/network/vpc"

    vpc_name = var.vpc_name
    vpc_cidr = "10.0.0.0/24"

    default_tags = merge(map(
        "Name", "scratch-test-vpc",
        "vpc_tag", "vpc"
    ), var.default_tags)
}

# Add a subnet
module "public_subnets" {
    source = "../../terraform/tf-lib/network/subnet"
    vpc_id                  = module.the_vpc.output_vpc_id
    subnets                 = var.public_subnets
    default_tags = merge(map(
        "Name", "scratch-test-subnet",
        "subnet_tag", "public"
    ), var.default_tags)
}

# tf-lib/network/vpc/main.tf
resource "aws_vpc" "vpc" {
    cidr_block = var.vpc_cidr
    enable_dns_support = true
    enable_dns_hostnames = true
    tags = merge(map(
        "module", "tf-lib/network/vpc"
    ), var.default_tags)
} 

每个模块的variable.tf 文件包含以下语句：

variable "default_tags" {}

Answer 1

该merge函数通过覆盖参数序列中定义的后一个映射来设置优先级：

merge接受任意数量的映射或对象，并返回包含所有参数的合并元素集的单个映射或对象。

如果多个给定映射或对象定义相同的键或属性，则参数序列中较靠后的一个优先。如果参数类型不匹配，则应用合并规则后，结果类型将是与属性的类型结构匹配的对象。

因此，为了允许您覆盖默认标签，您可以首先指定默认标签，如下所示：

# root variables.tf
variable "default_tags" {
    type = map
    default = {
        environment_type = "Dev Environment"
    }
} 


# root main.tf
provider "aws" {
    region = var.region
}

module "vpc" {
    source = "../../../../scratch/tags-pattern"
    vpc_name                = "scratch-test"
    public_subnets          = ["10.0.0.0/26"]

    default_tags = merge(var.default_tags, map(
        "Name", "scratch-test"
    ))
}

{}使用映射语法而不是map函数，上面的内容也可能看起来更清晰：

# root main.tf
provider "aws" {
    region = var.region
}

module "vpc" {
    source = "../../../../scratch/tags-pattern"
    vpc_name                = "scratch-test"
    public_subnets          = ["10.0.0.0/26"]

    default_tags = merge(var.default_tags, {
      Name = "scratch-test",
    })
}

正如map函数文档中提到的，该函数已被弃用，最终将被删除：

该函数已被弃用。{从 Terraform v0.12 开始，Terraform 语言具有使用和分隔符创建地图的内置语法} 。请改用内置语法。该map功能将在 Terraform 的未来版本中删除。