如何使用 VBS 捕获命令窗口的输出并通过播放的声音通知用户？

Question

我已成功设法使用 VBS 打开cmd以将数据写入数据库并按Enter两次键。

这是我的代码：

Set wshshell = wscript.CreateObject("WScript.Shell") 
Wshshell.run "cmd" 
wscript.sleep 100
wshshell.sendkeys "firebase-import --service_account C:\Users --database_url https://firebaseio.com  --json C:\Users\Zed\testing.json"
wscript.sleep 100
WshShell.SendKeys "{ENTER}"
WshShell.SendKeys "{ENTER}"

这是控制台输出：

firebase-import --service_account C:\Users\Zed\private-firebase-adminsdk-private --path /Jobs/Test --database_url https://private.firebaseio.com  --json C:\Users\Zed\testing.json
All data at https://private.firebaseio.com/Jobs/Test will be overwritten.
Press <enter> to proceed, Ctrl-C to abort.

Reading C:\Users\Zed\testing.json... (may take a minute)
Preparing JSON for import... (may take a minute)
Importing [==================================================] 100% (1/1)

Import completed.

我还设法使用 VBS 播放声音。这是代码：

Dim oPlayer
Set oPlayer = CreateObject("WMPlayer.OCX")

' Play audio
oPlayer.URL = "C:\Users\Zed\notify.mp3"
oPlayer.controls.play 
While oPlayer.playState <> 1 ' 1 = Stopped
  WScript.Sleep 100
Wend

' Release the audio file
oPlayer.close

现在，如何将这两者结合起来，以便仅Import completed在控制台窗口中显示消息时播放声音？

Answer 1

正如 Mofi 在评论中指出的那样，您可以禁用All data at https://private.firebaseio.com/Jobs/Test will be overwritten.让您远离发送按键的提示。您可以简单地使用 Windows Script HostRun方法：

Dim objWshShell
Dim sCommand

sCommand = "firebase-import --service_account C:\Users --database_url https://firebaseio.com  --json C:\Users\Zed\testing.json"

Set objWshShell = WScript.CreateObject("WScript.Shell")
objWshShell.Run sCommand, 1, True

您还可以将播放声音的代码包装成Sub：

Sub PlaySound(p_sURL)

    Dim oPlayer
    Set oPlayer = CreateObject("WMPlayer.OCX")
    
    ' Play audio
    oPlayer.URL = p_sURL
    oPlayer.Controls.play
    While oPlayer.playState <> 1 ' 1 = Stopped
      WScript.Sleep 100
    Wend
    
    ' Release the audio file
    oPlayer.Close

End Sub

您可以在以下之后调用此子程序objWshShell.Run sCommand, 1, true：

objWshShell.Run sCommand, 1, true
PlaySound ("C:\Users\Zed\notify.mp3")

编辑

为了确定导入过程的结果，您可以将输出重定向到文本文件：

sCommand = "cmd /c firebase-import --service_account C:\Users --database_url https://firebaseio.com  --json C:\Users\Zed\testing.json > C:\temp\output.txt"

然后，您可以阅读该文件并查找"Import Completed"：

Sub CheckOutput()
    Dim sOutput
    Dim objFSO, objFileReader

    Set objFSO  = CreateObject("Scripting.FileSystemObject")
    Set objFileReader = objFSO.OpenTextFile("c:\temp\output.txt", 1)
    sOutput = objFileReader.ReadAll
    objFileReader.Close

    If InStr(sOutput, "Import Completed") > 0 Then
        PlaySound ("C:\Users\Zed\notify.mp3")
    Else
        PlaySound ("C:\Users\Zed\error.mp3")
    End If

End Sub

您可以在运行以下命令后使用此子程序：

objWshShell.Run sCommand, 1, true
CheckOutput