使用 FSharpPlus 的 Reader monad 转换器示例

Question

我试图理解读者单子转换器。我正在使用FSharpPlus并尝试编译以下示例，该示例首先从阅读器环境中读取某些内容，然后执行一些异步计算，最后合并两个结果：

open FSharpPlus
open FSharpPlus.Data

let sampleReader = monad {
    let! value = ask
    return value * 2
}

let sampleWorkflow = monad {
    do! Async.Sleep 5000
    return 4
}

let doWork = monad {
    let! envValue = sampleReader
    let! workValue = liftAsync sampleWorkflow
    return envValue + workValue
}

ReaderT.run doWork 3 |> Async.RunSynchronously |> printfn "Result: %d"

有了这个，我在它显示的行出现编译错误，let! value = ask并显示以下完全无用的（至少对我来说）错误消息：

将默认类型“obj”应用于类型推断变量时，类型约束不匹配。没有与方法“op_GreaterGreaterEquals”匹配的重载。

已知返回类型：异步

已知类型参数：< obj , (int -> Async) >

感觉就像我只是在某个地方缺少一些操作员，但我无法弄清楚。

Answer 1

您的代码是正确的，但在这种情况下，F# 类型推断并不那么聪明。

如果您向 SampleReader 添加类型注释，它将正常编译：

let sampleReader : ReaderT<int,Async<_>> = monad {
    let! value = ask
    return value * 2
}

// val sampleReader : FSharpPlus.Data.ReaderT<int,Async<int>> =
//  ReaderT <fun:sampleReader@7>

更新：

看完你的评论后。如果您想要使其通用，首先必须声明您的函数inline，否则无法应用类型约束：

let inline sampleReader = monad ...

但这会带来第二个问题：常量不能被声明为内联（实际上有一种方法，但太复杂），只有函数可以。

所以最简单的方法就是让它成为一个函数：

let inline sampleReader () = monad ...

现在第三个问题是代码无法编译:)

同样，您可以给类型推断一个最小的提示，只需在调用站点说您期望 aReaderT<_,_>就足够了：

let inline sampleReader () = monad {
    let! value = ask
    return value * 2
}

let sampleWorkflow = monad {
    do! Async.Sleep 5000
    return 4
}

let doWork = monad {
    let! envValue = sampleReader () : ReaderT<_,_>
    let! workValue = liftAsync sampleWorkflow
    return envValue + workValue
}

ReaderT.run doWork 3 |> Async.RunSynchronously |> printfn "Result: %d"

结论：

在 F# 中定义泛型函数并不是那么简单的任务。如果您查看 F#+ 的源代码，您就会明白我的意思。

运行示例后，您将看到生成的所有约束，并且您可能会注意到通过使函数内联和通用来增加编译时间。

这些都表明我们正在将 F# 类型系统推向极限。

尽管 F#+ 定义了一些现成的泛型函数，并且这些函数有时可以以创建自己的泛型函数的方式进行组合，但这不是库的目标，我的意思是你可以，但然后你就就你自己而言，在某些情况下，比如探索性开发，这可能是有意义的。