如果下游作业失败,则将上游Jenkins/Hudson标记为失败

Question

我使用参数化触发插件来触发下游构建.

如果下游失败,如何指定我的上游作业应该失败？上游作业实际上是虚拟作业,参数传递给下游.

Answer 1

确保使用正确的步骤执行下游作业; 我发现自从我执行我的"后构建步骤"以来,我没有"阻止直到被触发的项目完成他们的构建"选项.将其更改为"构建任务"而不是"后构建任务",允许我在参数化触发器插件中找到您要查找的选项.

Answer 2

此代码将根据下游作业状态标记上游构建不稳定/失败.

/*************************************************
Description: This script needs to put in Groovy 
Postbuild plugin of Jenkins as a Post Build task.
*************************************************/

import hudson.model.*

void log(msg) {
  manager.listener.logger.println(msg)
}

def failRecursivelyUsingCauses(cause) {
     if (cause.class.toString().contains("UpstreamCause")) {
        def projectName = cause.upstreamProject
        def number = cause.upstreamBuild
        upstreamJob = hudson.model.Hudson.instance.getItem(projectName)
        if(upstreamJob) {
             upbuild = upstreamJob.getBuildByNumber(number)
             if(upbuild) {
                 log("Setting to '" + manager.build.result + "' for Project: " + projectName + " | Build # " + number)
                 //upbuild.setResult(hudson.model.Result.UNSTABLE)
                 upbuild.setResult(manager.build.result);
                 upbuild.save()

                 // fail other builds
                 for (upCause in cause.upstreamCauses) {
                     failRecursivelyUsingCauses(upCause)
                 }
             }
        } else {
            log("No Upstream job found for " + projectName);
        }
    }
}


if(manager.build.result.isWorseOrEqualTo(hudson.model.Result.UNSTABLE)) {
    log("****************************************");
    log("Must mark upstream builds fail/unstable");
    def thr = Thread.currentThread()
    def build = thr.executable
    def c = build.getAction(CauseAction.class).getCauses()

    log("Current Build Status: " + manager.build.result);
    for (cause in c) {
        failRecursivelyUsingCauses(cause)
    }
    log("****************************************");
}
else {
    log("Current build status is: Success - Not changing Upstream build status");
}

Answer 3

看一下以下响应：Fail hudson build with groovy script。您可以访问上游作业并使其构建失败，但是...请注意 Hudson/Jenkins 构建后操作现在不允许指定任何顺序：如果除了其他构建后之外还指定了您的 groovy 脚本操作，并且这些操作会影响构建的结果（即：测试结果的解析），那么如果 Jenkins 决定在您的 groovy 脚本之后运行它们，您将无法更新上游作业的状态。