在运行时创建表单和 WebBrowser

Question

我正在使用 Delphi 7 并尝试在运行时创建一个WebBrowserinside a Form，但无法使其工作。这是代码：

procedure TForm1.Button1Click(Sender: TObject);
var
  Form: TForm;
  Brws: TWebBrowser;
begin
  Form := TForm.Create(nil);
  try
    Form.Width := 500;
    Form.Height := 500;
    Form.BorderStyle := bsDialog;
    Form.Position := poScreenCenter;
    Form.Caption := 'Select the Option';
    Brws := TWebBrowser.Create(Form);
    Brws.ParentWindow := Form.Handle;
    TWinControl(Brws).Parent := Form;
    Brws.Align := alClient;
    Brws.AddressBar := False;
    Brws.MenuBar := False;
    Brws.StatusBar := False;
    Application.ProcessMessages;
    if Form.ShowModal = mrOk then
      Brws.Navigate('https://www.google.com');
  finally
    Form.Free;
  end;
end;

结果就像 WebBrowser 没有响应。我有一个白屏，没有错误消息。

请问，我错过了什么？谢谢！

Answer 1

您正在使用其ShowModal()方法显示表单，该方法是一个同步（又名阻塞）函数，在表单关闭之前不会退出。因此，Navigate()当表单打开时，您永远不会接到电话。

您有两个选择：

• 使用Show()代替ShowModal()。 Show()通知窗体显示自身，然后立即退出，允许在窗体打开时运行后续代码。因此，您将不得不摆脱 ，try...finally而是使用表单的OnClose事件在关闭时释放表单，例如：

procedure TForm1.Button1Click(Sender: TObject);
var
  Form: TForm;
  Brws: TWebBrowser;
begin
  Form := TForm.Create(Self);
  Form.Width := 500;
  Form.Height := 500;
  Form.BorderStyle := bsDialog;
  Form.Position := poScreenCenter;
  Form.Caption := 'Select the Option';
  Form.OnClose := BrowserFormClosed;

  Brws := TWebBrowser.Create(Form);
  TWinControl(Brws).Parent := Form;
  Brws.Align := alClient;
  Brws.AddressBar := False;
  Brws.MenuBar := False;
  Brws.StatusBar := False;

  Form.Show;
  Brws.Navigate('https://www.google.com');
end;

procedure TForm1.BrowserFormClosed(Sender: TObject;
  var Action: TCloseAction);
begin
  Action := caFree;
end;

• 否则，如果您想继续使用，ShowModal()则将调用移动Navigate()到表单OnShow或OnActivate事件中，例如：

procedure TForm1.Button1Click(Sender: TObject);
var
  Form: TForm;
  Brws: TWebBrowser;
begin
  Form := TForm.Create(nil);
  try
    Form.Width := 500;
    Form.Height := 500;
    Form.BorderStyle := bsDialog;
    Form.Position := poScreenCenter;
    Form.Caption := 'Select the Option';
    Form.OnShow := BrowserFormShown;

    Brws := TWebBrowser.Create(Form);
    TWinControl(Brws).Parent := Form;
    Brws.Align := alClient;
    Brws.AddressBar := False;
    Brws.MenuBar := False;
    Brws.StatusBar := False;

    Form.ShowModal;
  finally
    Form.Free;
  end;
end;

procedure TForm1.BrowserFormShown(Sender: TObject);
var
  Form: TForm;
  Brws: TWebBrowser;
begin
  Form := TForm(Sender);
  Brws := TWebBrowser(Form.Components[0]);
  Brws.Navigate('https://www.google.com');
end;