在OOXML中,粗体,斜体等格式可以(并且经常令人烦恼)在多个元素之间分割,如下所示:
<w:p>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve">This is a </w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve">bold </w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
<w:i/>
</w:rPr>
<w:t>with a bit of italic</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve"> </w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>paragr</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>a</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>ph</w:t>
</w:r>
<w:r>
<w:t xml:space="preserve"> with some non-bold in it too.</w:t>
</w:r>
</w:p>
我需要结合这些格式元素来产生这个:
<p><b>This is a mostly bold <i>with a bit of italic</i> paragraph</b> with some non-bold in it too.</p>
我最初的方法是在第一次遇到使用时写出开始格式化标记:
<xsl:text disable-output-escaping="yes"><b></xsl:text>
然后在我处理每个之后<w:r>,检查下一个,看看格式是否仍然存在.如果不是,请添加结束标记,方法与添加开始标记的方式相同.我一直认为必须有更好的方法来做到这一点,我会对任何建议表示感谢.
还应该提到我与XSLT 1.0绑定.
需要这个的原因是我们需要在XML文件转换为OOXML之前以及从OOXML转换出来之后对它进行比较.额外的格式化标签使它看起来好像在它们不是时进行了更改.
这是一个完整的XSLT 1.0解决方案:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common" xmlns:w="w"
exclude-result-prefixes="ext w">
<xsl:output omit-xml-declaration="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="w:p">
<xsl:variable name="vrtfPass1">
<p>
<xsl:apply-templates/>
</p>
</xsl:variable>
<xsl:apply-templates mode="pass2"
select="ext:node-set($vrtfPass1)/*"/>
</xsl:template>
<xsl:template match="w:r">
<xsl:variable name="vrtfProps">
<xsl:for-each select="w:rPr/*">
<xsl:sort select="local-name()"/>
<xsl:copy-of select="."/>
</xsl:for-each>
</xsl:variable>
<xsl:call-template name="toHtml">
<xsl:with-param name="pProps" select=
"ext:node-set($vrtfProps)/*"/>
<xsl:with-param name="pText" select="w:t/text()"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="toHtml">
<xsl:param name="pProps"/>
<xsl:param name="pText"/>
<xsl:choose>
<xsl:when test="not($pProps)">
<xsl:copy-of select="$pText"/>
</xsl:when>
<xsl:otherwise>
<xsl:element name="{local-name($pProps[1])}">
<xsl:call-template name="toHtml">
<xsl:with-param name="pProps" select=
"$pProps[position()>1]"/>
<xsl:with-param name="pText" select="$pText"/>
</xsl:call-template>
</xsl:element>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="/*" mode="pass2">
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:call-template name="processInner">
<xsl:with-param name="pNodes" select="node()"/>
</xsl:call-template>
</xsl:copy>
</xsl:template>
<xsl:template name="processInner">
<xsl:param name="pNodes"/>
<xsl:variable name="pNode1" select="$pNodes[1]"/>
<xsl:if test="$pNode1">
<xsl:choose>
<xsl:when test="not($pNode1/self::*)">
<xsl:copy-of select="$pNode1"/>
<xsl:call-template name="processInner">
<xsl:with-param name="pNodes" select=
"$pNodes[position()>1]"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:variable name="vbatchLength">
<xsl:call-template name="getBatchLength">
<xsl:with-param name="pNodes"
select="$pNodes[position()>1]"/>
<xsl:with-param name="pName"
select="name($pNode1)"/>
<xsl:with-param name="pCount" select="1"/>
</xsl:call-template>
</xsl:variable>
<xsl:element name="{name($pNode1)}">
<xsl:copy-of select="@*"/>
<xsl:call-template name="processInner">
<xsl:with-param name="pNodes" select=
"$pNodes[not(position()>$vbatchLength)]
/node()"/>
</xsl:call-template>
</xsl:element>
<xsl:call-template name="processInner">
<xsl:with-param name="pNodes" select=
"$pNodes[position()>$vbatchLength]"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
</xsl:template>
<xsl:template name="getBatchLength">
<xsl:param name="pNodes"/>
<xsl:param name="pName"/>
<xsl:param name="pCount"/>
<xsl:choose>
<xsl:when test=
"not($pNodes) or not($pNodes[1]/self::*)
or not(name($pNodes[1])=$pName)">
<xsl:value-of select="$pCount"/>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="getBatchLength">
<xsl:with-param name="pNodes" select=
"$pNodes[position()>1]"/>
<xsl:with-param name="pName" select="$pName"/>
<xsl:with-param name="pCount" select="$pCount+1"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
当此转换应用于以下XML文档时(基于提供的,但更复杂以显示如何覆盖更多边缘案例):
<w:p xmlns:w="w">
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve">This is a </w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve">bold </w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
<w:i/>
</w:rPr>
<w:t>with a bit of italic</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
<w:i/>
</w:rPr>
<w:t> and some more italic</w:t>
</w:r>
<w:r>
<w:rPr>
<w:i/>
</w:rPr>
<w:t> and just italic, no-bold</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t xml:space="preserve"></w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>paragr</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>a</w:t>
</w:r>
<w:r>
<w:rPr>
<w:b/>
</w:rPr>
<w:t>ph</w:t>
</w:r>
<w:r>
<w:t xml:space="preserve"> with some non-bold in it too.</w:t>
</w:r>
</w:p>
产生了想要的正确结果:
<p><b>This is a bold <i>with a bit of italic and some more italic</i></b><i> and just italic, no-bold</i><b>paragraph</b> with some non-bold in it too.</p>
说明:
pass1结果(为了便于阅读而缩进):
<p>
<b>This is a </b>
<b>bold </b>
<b>
<i>with a bit of italic</i>
</b>
<b>
<i> and some more italic</i>
</b>
<i> and just italic, no-bold</i>
<b/>
<b>paragr</b>
<b>a</b>
<b>ph</b> with some non-bold in it too.</p>
0.2.第二遍(在模式下执行"pass2")将任何批连续且具有相同名称的元素合并为具有该名称的单个元素.它以递归的方式调用自身在合并元素的子元素上 - 因此合并任何深度的批处理.
0.3.请注意:我们不(也不能)使用轴,following-sibling::或者preceding-sibling因为只有顶层的节点(要合并)才是兄弟姐妹.由于这个原因,我们将所有节点作为节点集处理.
0.4.这个解决方案是完全通用的 - 它可以在任何深度合并任意一批连续的同名元素 - 并且没有特定的名称是硬编码的.