Terraform 在地图列表中循环

Question

我有一个 Terraform 模块，可以生成地图输出列表：

object_ids = [
  {
    "object_id" = "xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxx"
    "upn" = "john@domain.com"
    "user" = "john"
  },
  {
    "object_id" = "xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxx"
    "upn" = "martin@domain.com"
    "user" = "martin"
  },
]

使用 for_each 我可以循环一个值来构建此资源：

resource "azurerm_role_assignment" "subread" {
    for_each = toset(module.user.map_object_ids[*].object_id)
    scope                = data.azurerm_subscription.primary.id
    role_definition_name = "Reader"
    principal_id         = each.value
}

但是我不知道如何循环多个值。

我尝试了以下方法来获取另一个需要 2 个不同输出值的资源：

resource "azurerm_role_assignment" "contribrg" {
    scope                = [for map in module.user.map_object_ids[*]: "${data.azurerm_subscription.primary.id}/resourceGroups/${lookup(map,"user")}"]
    role_definition_name = "Contributor"
    principal_id         = [for map in module.user.map_object_ids[*]: lookup(map,"object_id")]
}

出现以下错误：

Error: Incorrect attribute value type
module.user.map_object_ids is tuple with 2 elements
Inappropriate value for attribute "scope": string required.
Inappropriate value for attribute "principal_id": string required.

Answer 1

资源的一项基本要求for_each是，您正在使用的集合必须为您要创建的每个实例包含一个元素，因此不可能基于多个值进行重复，但幸运的是，我认为这实际上并不是您想要的在这里问。

相反，您似乎希望 的每个元素都有一个实例module.user.map_object_ids，因此我们需要处理的唯一额外问题是for_each期望获得对象映射而不是对象列表，因此它可以使用映射键作为每个实例的标识符。

for我们可以使用表达式将对象列表转换为对象映射，但我们需要标识嵌套对象的属性之一，该属性将用作每个元素的唯一键。我将user在这里使用，因为它似乎是一个很好的人类可理解的、配置选择的唯一标识符：

resource "azurerm_role_assignment" "contribrg" {
  for_each = { for obj in module.user.map_object_ids : obj.user => obj }

  scope                = "${data.azurerm_subscription.primary.id}/resourceGroups/${each.value.user}"
  role_definition_name = "Contributor"
  principal_id         = each.value.object_id
}

上面的表达式for会将对象列表投影到对象映射中，如下所示：

{
  "john" = {
    "object_id" = "xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxx"
    "upn" = "john@domain.com"
    "user" = "john"
  }
  "martin" = {
    "object_id" = "xxxxxxxx-xxxx-xxxx-xxxx-xxxxxxxx"
    "upn" = "martin@domain.com"
    "user" = "martin"
  }
}

然后在资源参数表达式中将each.key引用用户名（因为它们现在是键）each.value，同时将引用对象，因此我们可以使用它each.value.object_id来获取相应的对象标识符。

由此，Terraform 将计划使用以下地址创建资源实例：

• azurerm_role_assignment.contribrg["john"]
• azurerm_role_assignment.contribrg["martin"]

旁注：我发现有点令人困惑的是，当你的输出object_ids不只是返回 id 时，它会被命名。命名起来可能会更清楚objects。