编写相当于mul/imul的VOP

Question

因此， mul 和 imul 指令都将机器字相乘，并将结果和溢出都存储在某些寄存器中（例如参见https://c9x.me/x86/html/file_module_x86_id_210.html）。我正在尝试编写一个可以完全使用此信息并返回 2 个值的 vop。这可能吗？我找不到有关如何使 vop 返回多个值的任何信息。如果有人可以展示整个事情的样子，我也会很感激。

编辑：所以我想出了一些东西，但它仍然不够好。我会把它贴在这里，然后解释问题。

(defpackage #:fixmul
  (:use #:CL)
  (:export #:fixmul))

(in-package #:fixmul)


(sb-c:defknown fixmul (fixnum fixnum) (values fixnum fixnum &optional)
    (sb-c:foldable sb-c:flushable sb-c:movable)
  :overwrite-fndb-silently t)

(in-package #:sb-vm)

(define-vop (fixmul:fixmul)
  (:policy :fast-safe)
  (:translate fixmul:fixmul)
  (:args (x :scs (signed-reg) :target eax)
         (y :scs (signed-reg signed-stack)))
  (:arg-types fixnum fixnum)
  (:args-var args)
  (:temporary (:sc signed-reg :offset eax-offset :target quo
               :from (:argument 0) :to (:result 0)) eax)
  (:temporary (:sc signed-reg :offset edx-offset :target rem
               :from (:argument 0) :to (:result 1)) edx)
  (:results (quo :scs (signed-reg))
            (rem :scs (signed-reg)))
  (:result-types fixnum fixnum)
  (:note "inline (unsigned-byte 64) arithmetic")
  (:vop-var vop)
  (:save-p :compute-only)
  (:generator 5
              (move eax x)
              (inst mul eax y)
              (move quo eax)
              (move rem edx)))

(in-package #:fixmul)

(defun fixmul (a b)
  (fixmul a b))

所以，这反汇编为：

> (disassemble 'fixmul)
; disassembly for FIXMUL
; Size: 35 bytes. Origin: #x52C42F4F                          ; FIXMUL
; 4F:       48F7E7           MUL RAX, RDI
; 52:       488BFA           MOV RDI, RDX
; 55:       48D1E0           SHL RAX, 1
; 58:       48D1E7           SHL RDI, 1
; 5B:       488BD0           MOV RDX, RAX
; 5E:       488D5D10         LEA RBX, [RBP+16]
; 62:       B904000000       MOV ECX, 4
; 67:       BE17001050       MOV ESI, #x50100017              ; NIL
; 6C:       F9               STC
; 6D:       488BE5           MOV RSP, RBP
; 70:       5D               POP RBP
; 71:       C3               RET
NIL

这还不错，但我不明白我在 sbcl 方面所做的大部分事情，特别是 - 为什么我会得到这个 LEA RBX、[RBP+16] 和 MOV ESI、#x50100017
指令？

EDIT2：似乎这些指令主要是关于返回 2 个值。然而，整个事情在某种意义上是有问题的，因为它使用 CL 本机 fixnums 等，而不仅仅是原始机器词。我不确定如何解决这个问题，这就是为什么我不给出自我答案。

Answer 1

尝试：

(defpackage #:fixmul
  (:use #:CL)
  (:export #:fixmul))

(in-package #:fixmul)

(sb-c:defknown fixmul ((signed-byte 64) (signed-byte 64)) 
               (values (signed-byte 64) (signed-byte 64) &optional)
               (sb-c:foldable sb-c:flushable sb-c:movable))

(in-package #:sb-vm)

(define-vop (fixmul:fixmul)
  (:policy :fast-safe)
  (:translate fixmul:fixmul)
  (:args (x :scs (signed-reg) :target eax)
         (y :scs (signed-reg signed-stack)))
  (:arg-types signed-num signed-num)
  ; (:args-var args)
  (:temporary (:sc signed-reg :offset eax-offset :target quo
               :from (:argument 0) :to (:result 0)) eax)
  (:temporary (:sc signed-reg :offset edx-offset :target rem
               :from (:argument 0) :to (:result 1)) edx)
  (:results (quo :scs (signed-reg))
            (rem :scs (signed-reg)))
  (:result-types signed-num signed-num)
  (:note "inline (unsigned-byte 64) arithmetic")
  (:vop-var vop)
  (:save-p :compute-only)
  (:generator 5
              (move eax x)
              (inst mul eax y)
              (move quo eax)
              (move rem edx)))

(in-package #:fixmul)

(defun fixmul (a b)
  (fixmul a b))

现在：（反汇编'fixmul）

显示：

; disassembly for FIXMUL
; 02E2D561:       498BC0           MOV RAX, R8                ; no-arg-parsing entry point
;       64:       49F7E1           MUL RAX, R9
;       67:       488BCA           MOV RCX, RDX
;       6A:       486BD002         IMUL RDX, RAX, 2
;       6E:       710E             JNO L0
;       70:       488BD0           MOV RDX, RAX
;       73:       4C8D1C2540060020 LEA R11, [#x20000640]      ; ALLOC-SIGNED-BIGNUM-IN-RDX
;       7B:       41FFD3           CALL R11
;       7E: L0:   486BF902         IMUL RDI, RCX, 2
;       82:       710E             JNO L1
;       84:       488BF9           MOV RDI, RCX
;       87:       4C8D1C2518070020 LEA R11, [#x20000718]      ; ALLOC-SIGNED-BIGNUM-IN-RDI
;       8F:       41FFD3           CALL R11
;       92: L1:   488D5D10         LEA RBX, [RBP+16]
;       96:       B904000000       MOV ECX, 4
;       9B:       BE17001020       MOV ESI, 537919511
;       A0:       F9               STC
;       A1:       488BE5           MOV RSP, RBP
;       A4:       5D               POP RBP
;       A5:       C3               RET
;       A6:       0F0B0A           BREAK 10                   ; error trap
;       A9:       02               BYTE #X02
;       AA:       18               BYTE #X18                  ; INVALID-ARG-COUNT-ERROR
;       AB:       54               BYTE #X54                  ; RCX
NIL

正如你可以看到的

; 73: 4C8D1C2540060020 LEA R11, [#x20000640] ; ALLOC-SIGNED-BIGNUM-IN-RDX

和

; 87: 4C8D1C2518070020 LEA R11, [#x20000718] ; ALLOC-SIGNED-BIGNUM-IN-RDI

abignum已(and integer (not fixnum))分配。由于我有一个 64 位系统，一个 bignum 适合一个机器字。32 位系统上的反汇编会有所不同。在这种情况下，您可以(signed-byte 32)在 中指定sb-c:defknown fixmul。

你的结果类型和arg类型也可以不同（这样，如果你知道你的输入值会很小，那么你仍然可以获得接近最大值的结果(signed-byte 32)。）：

(sb-c:defknown fixmul ((signed-byte 32) (signed-byte 32)) 
               (values (signed-byte 64) (signed-byte 64) &optional)
               (sb-c:foldable sb-c:flushable sb-c:movable))

一些测试：

(fixmul 10000000000000000 100000000000000000)

> 4089650035136921600
  54210108624275


(fixmul 20 -200000)

> -4000000
  19

注意：我必须注释掉(:args-var args)并删除才能:overwrite-fndb-silently t使我的代码正常工作。这可能是由于我的 sbcl 与你的版本不同所致。