试图从 Twitter 的 GET 请求中获取 ResponseText

Question

我正在努力提高我对 VBA 的了解，学习 GET、POST 和其他东西，因为我看过很多例子，但无法理解我做错了什么。可能是 Oauth 部分。

主要问题是我只是一个 Excel 人。我不是网络开发人员，所以我的知识几乎为零，而且可能我错过了很多基本的东西。

我希望这个问题不要太宽泛。

背景：我正在尝试从推文中获取 JSON 对象的 ResponseText。信息是公开的，您无需登录即可查看我想获取的信息，也不需要 Twitter 帐户。

为了测试，我正在使用这条推文：https : //twitter.com/StackOverflow/status/1273391252357201922

我想要什么：使用开发人员工具检查代码（我使用的是 Firefox），我已经看到了：

此 GET 请求返回此 ResponseText：

所以我想将该 ResponseText 放入 VBA。

我的代码：在这里检查不同的代码，我已经建立了这个：

Sub test()
    Dim MiHttp As Object
    Dim MiUrl As String
    Set MiHttp = CreateObject("MSXML2.XMLHTTP")
    
    MiUrl = "https://api.twitter.com/2/timeline/conversation/1273391252357201922.json?include_profile_interstitial_type=1&include_blocking=1&include_blocked_by=1&include_followed_by=1&include_want_retweets=1&include_mute_edge=1&include_can_dm=1&include_can_media_tag=1&skip_status=1&cards_platform=Web-12&include_cards=1&include_ext_alt_text=true&include_reply_count=1&tweet_mode=extended&include_entities=true&include_user_entities=true&include_ext_media_color=true&include_ext_media_availability=true&send_error_codes=true&simple_quoted_tweet=true&count=20&ext=mediaStats%2ChighlightedLabel&include_quote_count=true"
    
    With MiHttp
        .Open "GET", MiUrl
        .Send
        DoEvents
     
        Debug.Print .responseText
    End With


    MiHttp.abort
    Set MiHttp = Nothing
End Sub

它运行，没有编码错误，但我明白了：

{"errors":[{"code":200,"message":"Forbidden."}]}

所以我尝试添加带有授权的 RequestHeaders：

在之前添加这行代码.Send：

.setRequestHeader "authorization", "Bearer AAAAAAAAAAAAAAAAAAAAANRILgAAAAAAnNwIzUejRCOuH5E6I8xnZz4puTs%3D1Zv7ttfk8LF81IUq16cHjhLTvJu4FA33AGWWjCpTnA"

然后我在调试器中得到这个： {"errors":[{"message":"Rate limit exceeded","code":88}]}

因此，检查了 Twitter 库中寻找有关Bearer内容和令牌信息的开发人员，我必须承认我不知所措。

关于承载

关于代币

现在我迷路了。我认为这会很容易，因为这是公开信息，每个人都可以从任何推文中手动获取，无需使用任何应用程序或登录 Twitter，但看起来我错了，我有点迷茫。

最后一个问题： 我想知道我是否可以通过任何方式获得那个Bearer令牌，然后将它应用到我的代码中，以获得那个 JSON responseText（处理 JSON 并了解它们将是一个完全不同的问题，超出范围这里）。

我想用 VBA 来实现这一点，没有其他应用程序或语言，因为我不知道。

其实我对全文都不感兴趣，只对红线包围的部分感兴趣。

寻找一些帮助，指导，光。

提前致谢，我希望这个问题不会太宽泛。

谢谢！

更新：测试了@ChristosLytras 的回答。我收到此错误：

2020 年 7 月更新：现在工作网址是：

https://api.twitter.com/2/timeline/conversation/1273391252357201922.json?include_profile_interstitial_type=1&include_blocking=1&include_blocked_by=1&include_followed_by=1&include_want_retweets=1&include_mute_edge=1&include_can_dm=1&include_can_media_tag=1&skip_status=1&cards_platform=Web-12&include_cards=1&include_ext_alt_text=true&include_reply_count=1&tweet_mode=extended&include_entities=true&include_user_entities=true&include_ext_media_color=true&include_ext_media_availability=true&send_error_codes=true&simple_quoted_tweet=true&count=20&ext=mediaStats%2ChighlightedLabel&include_quote_count=true

Answer 1

您必须在请求标头中传递有效的获取的访客令牌以及授权Bearer，然后您才会收到响应。Twitter 公共 API 承载永远不会改变。

为了为每个请求获取新的有效访客令牌，您可以使用代替HEAD发出请求，并使用正则表达式（如 ）读取cookie 。每次调用时都会获取 cookie 标头。您无法使用，因为它使用缓存，并且每次请求时您都不会获得新的访客令牌WinHttp.WinHttpRequest.5.1MSXML2.XMLHTTPgtgt=(\d+);MSXML2.XMLHTTPHEAD.

使用Excel 2013和VBA 7.1测试工作代码：

Dim MiHttp As Object
Dim GuestTokenRE As Object
Dim MiUrl As String

Set MiHttp = CreateObject("WinHttp.WinHttpRequest.5.1")
Set GuestTokenRE = CreateObject("VBScript.RegExp")

MiUrl = "https://api.twitter.com/2/timeline/conversation/1273391252357201922.json?include_profile_interstitial_type=1&include_blocking=1&include_blocked_by=1&include_followed_by=1&include_want_retweets=1&include_mute_edge=1&include_can_dm=1&include_can_media_tag=1&skip_status=1&cards_platform=Web-12&include_cards=1&include_ext_alt_text=true&include_reply_count=1&tweet_mode=extended&include_entities=true&include_user_entities=true&include_ext_media_color=true&include_ext_media_availability=true&send_error_codes=true&simple_quoted_tweet=true&count=20&ext=mediaStats%2ChighlightedLabel&include_quote_count=true"

With MiHttp
    ' Make a HEAD request with no cache to get the Guest Token cookie
    .Open "HEAD", "https://twitter.com", False
    .setRequestHeader "User-Agent", "Firefox"
    .setRequestHeader "Pragma", "no-cache"
    .setRequestHeader "Cache-Control", "no-cache"
    .Send

    DoEvents
    
    ' Use a regular expression to extract guest token from response headers
    GuestTokenRE.Pattern = "Set-Cookie: gt=(\d+);"
    GuestTokenRE.IgnoreCase = True
    
    Dim matches as Object
    Set matches = GuestTokenRE.Execute(.getAllResponseHeaders())
    
    If matches.Count = 1 Then
        Dim guestToken As String
        guestToken = matches.Item(0).Submatches.Item(0)
        
        ' Print the Guest Token for validation
        Debug.Print "Got Guest Token", guestToken
        
        ' Now we have a valid guest token, make the request
        .Open "GET", MiUrl, False
        ' Authorization Bearer is always the same
        .setRequestHeader "authorization", "Bearer AAAAAAAAAAAAAAAAAAAAANRILgAAAAAAnNwIzUejRCOuH5E6I8xnZz4puTs%3D1Zv7ttfk8LF81IUq16cHjhLTvJu4FA33AGWWjCpTnA"
        .setRequestHeader "x-guest-token", guestToken
        .Send
        DoEvents
    
        Debug.Print "Got response", .responseText
    Else
        Debug.Print "Could not fetch Guest Token"
    End If

End With

MiHttp.abort

Set MiHttp = Nothing
Set GuestTokenRE = Nothing

关于80072efe错误

你得去WinHttp.WinHttpRequest.5.1上班了。该80072efe错误表明连接异常终止，您可以在此处阅读有关它的更多信息。我没有遇到这样的问题，因此这些错误不是源自端点。

正在运行的代码的屏幕截图