在Mathematica中选择条件查询

Question

使用以下列表,

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

是否可以选择第二个值> 3的列表.下面的期望输出

{5, 6, 7, 8}

调整以下代码,该代码当前提取列表中的所有值> 2

Select[#, # > 2 &] & /@ list[[2 ;;]

可以在Mathematica中找到条件数据操作的复杂解决方案

Answer 1

或者,使用 Select

Select[list, #[[2]] > 3 &]

产量

{{5, 6, 7, 8}}

Answer 2

在这种情况下Select,这是最简单的方法,但Pick也可用于相关问题.

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

Pick[list, #>3& /@ list[[All, 2]] ]

为了解释,Pick采用相同形状的两个列表(或嵌套列表),并返回第一个对应元素的第一个元素True.(它也可以接受第三个参数来匹配除True.之外的元素.)

这里,用第一列提取,list[[All, 2]]然后将测试#>3&映射到每个元素.然后将其用作选择列表.

响应500的评论,要求对Select方法进行概括:

selectByColumn[array_, index_, value_, range_] :=
  Select[array, #[[index]] > value &][[All, range]]

这允许指定:

• array :从中提取的输入数组
• index :用于比较的列索引
• value :要比较的值
• range:Part从每个结果行中提取的规范

Answer 3

不同解决方案的速度比较

有趣的是,Select对于解压缩阵列总是工作得更快,对于大型阵列,差异大约是一个数量级!点击下表放大:

时序测试代码:

solutions = Hold[
   Select[list, #[[2]] > 3 &],
   Cases[list, _List?(#[[2]] > 3 &)],
   Cases[list, x_List /; x[[2]] > 3],
   Cases[list, {_, x_, ___} /; x > 3],
   Cases[list, {_, _?(# > 3 &), ___}],
   Cases[list, {x___} /; List[x][[2]] > 3],
   Pick[list, UnitStep[list[[All, 2]] - 3], 1],
   Pick[list, # > 3 & /@ list[[All, 2]]]
   ];
testCases = Hold[
   {"Packed Reals", RandomReal[{0, 5}, {dim, dim}]},
   {"Unpacked Reals", 
    Developer`FromPackedArray@RandomReal[{0, 5}, {dim, dim}]},
   {"Packed Integers", RandomInteger[{0, 5}, {dim, dim}]},
   {"Unpacked Integers", 
    Developer`FromPackedArray@RandomInteger[{0, 5}, {dim, dim}]},
   {"Rationals", 
    Rationalize[#, .001] & /@ RandomReal[{0, 5}, {dim, dim}]}
   ];
timing := 
  Function[Null, 
   If[(time = First[Timing[Do[#;, {n}]]]) < .3, 
     Print["Too small timing for ", n, " iterations (dim=", dim, 
      ") of ", HoldForm[#], ": ", time, " seconds!"]; time, time]/n, 
   HoldFirst];
generateTable := 
 Labeled[TableForm[
   Transpose@
    Table[list = testCases[[i, 2]]; 
     tmgs = List @@ (timing /@ solutions); 
     d = Last@MantissaExponent[Min[tmgs]] - 3; 
     Row[{Round[10^-d*#], ".\[Times]", Superscript[10, d]}] & /@ 
      tmgs, {i, 1, Length[testCases]}], 
   TableHeadings -> {List @@ (HoldForm /@ solutions), 
     List @@ testCases[[All, 1]]}, TableAlignments -> Right], 
  Row[{"Average timings for ", dim, "\[Times]", dim, " list"}], Top]

Column[{dim = 5; n = 30000; generateTable, dim = 100; n = 3000; 
  generateTable, dim = 1000; n = 150; generateTable}, Left, 1, 
 Frame -> All, FrameStyle -> Gray]