有没有办法使用 Delphi 的 for .. in .. 来迭代 FireDAC 的 TFParams 呢？

Question

使用 Delphi 10.2（东京），我只想做一些简单的事情：

function ShowFinalSQL(const qry: TFDQuery): String;
var
  cSQL: String;
  oParam: TFDParam;
begin
  cSQL := qry.SQL.Text;
  for oParam in qry.Params do
    cSQL := cSQL.Replace(oParam.Name, oParam.Value);
  Result := cSQL;
end;

但我总是收到错误消息：

[dcc32 Error] DTUtilBD.pas(3115): E2010 Incompatible types: 'TFDParam' and 'TCollectionItem'

有没有办法做到这一点？

Answer 1

TFDQuery.Params是 a TFDParams，它可以用for..in循环迭代，因为它有一个公共GetEnumerator()方法。但是，该方法继承自TCollection以迭代TCollectionItem项目，因此它不是专门用于TFDParam项目的（请随意提交有关该疏忽的错误报告）。

因此，当循环迭代尝试将枚举器的Current属性分配给您的oParam变量时，它无法编译，因为TCollectionItem无法将 a 分配给 a TFDParam。这正是编译器错误所抱怨的。

您的代码基本上被编译为-好像它是这样编写的：

function ShowFinalSQL(const qry: TFDQuery): String;
var
  cSQL: String;
  oParam: TFDParam;
  cEnum: TCollectionEnumerator;
begin
  cSQL := qry.SQL.Text;
  //for oParam in qry.Params do
  cEnum := qry.Params.GetEnumerator;
  while cEnum.MoveNext do
  begin
    oParam := cEnum.Current; // <-- ERROR HERE - cEnum.Current is TCollectionItem!
    cSQL := cSQL.Replace(oParam.Name, oParam.Value);
  end;
  Result := cSQL;
end;

要解决此问题，您需要将oParam变量更改为 aTCollectionItem而不是 a TFDParam。当您想访问任何TFDParam特定成员时，您只需键入它，例如：

function ShowFinalSQL(const qry: TFDQuery): String;
var
  cSQL: String;
  oParam: TCollectionItem;
begin
  cSQL := qry.SQL.Text;
  for oParam in qry.Params do
    cSQL := cSQL.Replace(TFDParam(oParam).Name, TFDParam(oParam).Value);
  Result := cSQL;
end;

或者：

function ShowFinalSQL(const qry: TFDQuery): String;
var
  cSQL: String;
  oItem: TCollectionItem;
  oParam: TFDParam;
begin
  cSQL := qry.SQL.Text;
  for oItem in qry.Params do
  begin
    oParam := TFDParam(oItem);
    cSQL := cSQL.Replace(oParam.Name, oParam.Value);
  end;
  Result := cSQL;
end;

更新：或者，如果您想避免手动类型转换，您可以使用absolute：

function ShowFinalSQL(const qry: TFDQuery): String;
var
  cSQL: String;
  oItem: TCollectionItem;
  oParam: TFDParam absolute oItem;
begin
  cSQL := qry.SQL.Text;
  for oItem in qry.Params do
  begin
    cSQL := cSQL.Replace(oParam.Name, oParam.Value);
  end;
  Result := cSQL;
end;