如何为 flex/bison 实现更好的错误消息

Question

我需要为我正在编写的语法的语法错误提供正确的错误消息。我发现我可以为 flex 文件中的新行定义一个规则（？不确定术语），增加行号计数器，我可以在yyerror(const char*). 但是，我还需要知道错误发生的确切位置以获得更好的错误消息。这就是我希望错误消息的样子：

Syntax error on line X:
SOME ERRONEOUS TEXT ON LINE X
_______________^
Expected other text.

如何获取列信息以及错误行上的文本？

先感谢您。

Answer 1

输出意外和预期的令牌

只需使用

#define YYERROR_VERBOSE 1

yyerror 输出已经类似于

syntax error, unexpected '+', expecting NUM or '('  

打印行号

要打印当前行号，您可以使用 yylineno。你需要声明它

extern int yylineno;

在 .y 文件中。

在 .l flex 文件中，您需要添加：

%option yylineno

打印列

要获取列信息，您必须跟踪词法分析器文件中的列。因此，在您阅读了一个标记后，您可以简单地添加标记的长度（例如，通过使用 strlen(yytext)）。对于错误报告，您对标记开始的列感兴趣，因此您需要在读取标记之前设置并记住列位置的第二个变量。

你可以使用一个简单的宏：

#define HANDLE_COLUMN column = next_column; next_column += strlen(yytext)

打印电流输入线

要打印当前输入行，您必须自己跟踪它。您可以自己从 yyin 读取行并通过相应地定义宏 YY_INPUT 在词法分析器中使用此数据。有一个很好的答案/sf/answers/3031216891/解释了它是如何工作的。

作者还展示了如何使用宏 YY_USER_ACTION 确定当前列的示例。

简单示例

一个可以处理加法和减法的简单、自包含的计算器示例可能如下所示

输入 5+3+2+1 它作为输出给出：

5+3+2+1
=11

诸如“5+2++1”之类的错误输入结果为输出：

error: syntax error, unexpected '+', expecting NUM or '(' in line 3, column 5
5+2++1
____^

计算量

%{
    #include "y.tab.h"
    extern int yylval;
    static int next_column = 1;
    int column = 1;

    #define HANDLE_COLUMN column = next_column; next_column += strlen(yytext)

    char *lineptr = NULL;
    size_t n = 0;
    size_t consumed = 0;
    size_t available = 0;

    size_t min(size_t a, size_t b);
    #define YY_INPUT(buf,result,max_size) {\
        if(available <= 0) {\
            consumed = 0;\
            available = getline(&lineptr, &n, yyin);\
            if (available < 0) {\
                if (ferror(yyin)) { perror("read error:"); }\
                    available = 0;\
                }\
        }\
        result = min(available, max_size);\
        strncpy(buf, lineptr + consumed, result);\
        consumed += result;\
        available -= result;\
    }
%}

%option noyywrap noinput nounput yylineno

%%

[\t ]+   { HANDLE_COLUMN; }
[0-9]+   { HANDLE_COLUMN; yylval = atoi(yytext);  return NUM; }
\n       { HANDLE_COLUMN; next_column = 1; return '\n'; }
.        { HANDLE_COLUMN; return yytext[0]; }

%%

size_t min(size_t a, size_t b) {
    return b < a ? b : a;
}

钙化

%{
    #include <stdio.h>
    int yylex(void);
    void yyerror(const char *s);
    extern int yylineno;
    extern int column;
    extern char *lineptr;
    #define YYERROR_VERBOSE 1
%}

%token NUM
%left '-' '+'
%left '(' ')'

%%
LINE:                   { $$ = 0; }
       | LINE EXPR '\n' { printf("%s=%d\n", lineptr, $2); }
       | LINE '\n'
       ;


EXPR:    NUM            { $$ = $1; }
     |   EXPR '-' EXPR  { $$ = $1 - $3; }
     |   EXPR '+' EXPR  { $$ = $1 + $3; }
     |   '(' EXPR ')'   { $$ = $2; }
     ;


%%

void yyerror(const char *str)
{
    fprintf(stderr,"error: %s in line %d, column %d\n", str, yylineno, column);
    fprintf(stderr,"%s", lineptr);
    for(int i = 0; i < column - 1; i++)
        fprintf(stderr,"_");
    fprintf(stderr,"^\n");
}

int main()
{
   yyparse();
   free(lineptr);
}

构建命令

根据您的系统，构建命令类似于以下内容：

flex calc.l  
yacc -d calc.y
cc -Wextra -Wall lex.yy.c y.tab.c