将 FetchContent_Declare 与 CMAKE_ARGS 一起使用

Question

我正在使用cmake v3.13，我想将我ExternalProject_Add()的SEAL库更改为：

include(FetchContent)
# Get the seal library
set(SEAL "seal")
FetchContent_Declare(
        ${SEAL}
        GIT_REPOSITORY  https://github.com/microsoft/SEAL
        GIT_TAG         v3.5.2

)
FetchContent_GetProperties(${SEAL})
if(NOT ${SEAL}_POPULATED)
    FetchContent_Populate(${SEAL})
    add_subdirectory(${${SEAL}_SOURCE_DIR} ${${SEAL}_BINARY_DIR})
endif()

当我使用时，ExternalProject_Add()我已经使用过CMAKE_ARGS -DBUILD_SHARED_LIBS=ON并且这不适FetchContent_Declare()用于仅下载库。

该SEAL V3.5.2的CMakeLists.txt使用它来检查，如果要构建一个共享库的需求：

# Should we build also the shared library?
set(BUILD_SHARED_LIBS_STR "Build shared library")
option(BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS_STR} OFF)
if(MSVC AND BUILD_SHARED_LIBS)
    message(WARNING "This build system only supports a static build; disabling `BUILD_SHARED_LIBS`")
    set(BUILD_SHARED_LIBS OFF CACHE BOOL ${BUILD_SHARED_LIBS_STR} FORCE)
endif()

# Conditionally build the shared library
if(BUILD_SHARED_LIBS)
    add_library(seal_shared SHARED $<TARGET_OBJECTS:seal_obj>)
    set_target_properties(seal_shared PROPERTIES OUTPUT_NAME seal)
    seal_set_version(seal_shared)
    seal_set_soversion(seal_shared)
    seal_set_language(seal_shared)
    seal_set_include_directories(seal_shared)
    seal_link_threads(seal_shared)

    # Conditionally add MSGSL include directory to build interface
    if(SEAL_USE_MSGSL AND NOT MSVC)
        target_include_directories(seal_shared PUBLIC $<BUILD_INTERFACE:${MSGSL_INCLUDE_DIR}>)
    endif()

    if(SEAL_USE_ZLIB AND NOT MSVC)
        # In the shared build we link zlibstatic into the shared library
        target_link_libraries(seal_shared PRIVATE zlibstatic)
    endif()

    seal_install_target(seal_shared SEALTargets)
endif()

有没有办法使用下载SEAL库FetchContent_Declare()，然后在构建时使用一些CMakeLists设置将CMAKE_ARGS -DBUILD_SHARED_LIBS=ON参数传递给下载的库？

Answer 1

在顶层构建某个项目时，您可以使用命令行选项将参数传递给它

-D<VARIABLE>=<VALUE>

（ExternalProject_Add构建项目“好像”顶级，因此选项传递在技术上是相同的）。

当使用方法将某个项目构建为子项目add_subdirectory时，您可以使用相同的命令行选项

-D<VARIABLE>=<VALUE>

对于顶级项目，此参数也将传播到子项目。

如果不需要将参数传递给顶级项目，那么您可以CMakeLists.txt使用set(CACHE INTERNAL)命令流模拟内部的参数设置：

set(<PARAMETER> <VALUE> CACHE INTERNAL "<some description>")

确保在 add_subdirectory()调用之前发出此行（否则它不会影响子项目）。

因此，在您的情况下，您可以使用以下代码：

if(NOT ${SEAL}_POPULATED)
    FetchContent_Populate(${SEAL})
    # Make subproject to use 'BUILD_SHARED_LIBS=ON' setting.
    set(BUILD_SHARED_LIBS ON CACHE INTERNAL "Build SHARED libraries")
    add_subdirectory(${${SEAL}_SOURCE_DIR} ${${SEAL}_BINARY_DIR})
endif()

当顶级项目不使用子项目的参数集时，以上所有内容都可以完美运行。

如果顶级项目和子项目都受到同一个参数的影响，并且您只想为子项目硬编码参数，那么事情会变得更加复杂。add_subdirectory调用后需要恢复参数：

if(NOT ${SEAL}_POPULATED)
    FetchContent_Populate(${SEAL})

    # Store the old value of the 'BUILD_SHARED_LIBS'
    set(BUILD_SHARED_LIBS_OLD ${BUILD_SHARED_LIBS})
    # Make subproject to use 'BUILD_SHARED_LIBS=ON' setting.
    set(BUILD_SHARED_LIBS ON CACHE INTERNAL "Build SHARED libraries")

    add_subdirectory(${${SEAL}_SOURCE_DIR} ${${SEAL}_BINARY_DIR})

    # Restore the old value of the parameter
    set(BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS_OLD} CACHE BOOL "Type of libraries to build" FORCE)
endif()

# ...

# The library will be created according to "original" value for BUILD_SHARED_LIBS option.
add_library(top_lib top_lib.c)

请注意，在恢复参数的情况下，使用set(CACHE TYPE FORCE)命令流而不是set(CACHE INTERNAL)。这不仅恢复了 CACHE 变量的值，还恢复了它的类型，这在 CMake GUI 中显示。