如何输出使用 for_each 创建的资源的多个实例的属性？

Question

假设我有一个环境地图要提供给 for_each

environments = {
    "0" = "dev"
    "1" = "test"
    "2" = "stage"
}

然后，无论出于何种原因，我想为每个环境创建一个 Azure 资源组。

resource "azurerm_resource_group" "resource_group" {
  for_each = var.environments
  name     = "${var.resource-group-name}-${each.value}-rg"
  location = var.location
}

我如何获得输出？我已经尝试了新的splat，但没有成功。

output "name" {
  value = "${azurerm_resource_group.resource_group[*].name}"
}

output "id" {
  value = "${azurerm_resource_group.resource_group[*].id}"
}

output "location" {
  value = "${azurerm_resource_group.resource_group[*].location}"
}

错误：不支持的属性

in output "id":
   6:   value = "${azurerm_resource_group.resource_group[*].id}"

This object does not have an attribute named "id".

如何输出使用 for_each 创建的资源的多个实例的属性？

Answer 1

这[*]是从对象列表中提取属性的简写。for_each使资源显示为对象的映射，因此该[*]运算符不合适。

但是，for表达式是一种更通用的机制，可以通过对源集合的每个元素求任意表达式来将列表或映射转换为另一个列表或映射。

因此，我们可以将对象映射简化为这些对象的名称azurerm_resource_group映射，如下所示：

output "name" {
  value = { for k, group in azurerm_resource_group.resource_group: k => group.name }
}

您的输入映射使用数字索引作为键，这是不常见的但允许的。因此，输出的结果值将如下所示：

{
  "0" = "something-dev-rg"
  "1" = "something-test-rg"
  "2" = "something-stage-rg"
}

更常见的是，映射for_each包含一个有意义的名称作为键，以便通过该有意义的名称而不是递增整数来标识结果实例。如果您更改配置以使用环境名称作为键，则名称映射将如下所示：

{
  "dev"   = "something-dev-rg"
  "test"  = "something-test-rg"
  "stage" = "something-stage-rg"
}