VCL CheckListBox 传递选中的 Item 并删除它

Question

大家好，我是 Delphi 初学者，我有一个简单的问题，因为在网上为 Delphi 寻找一些东西似乎很难。

我有一个 CheckListBox，当我点击一个项目的复选框时，我想将它传递给另一个表单，假设创建了 form2。我有 2 个按钮：

1. 删除 - 它应该删除选定的项目，以便生成表单的项目。如何删除选定的项目？

2. 编辑条目 - 我需要将选中的项目值传递到另一个表单，在那里我可以编辑这些值并将其另存为新的。如何将选定项中的值传递到另一个表单？

泰褪色。

Answer 1

这是一个更好的方法：

1. 创建一个新的 VCL 应用程序。

2. 添加一个TCheckListBox控件，上面有几个项目：

   

3. TActionList在窗体上放置一个组件。

4. 创建两个操作：aDelete和aRename。将他们的标题设置为Delete...和Rename...，将他们的提示设置为Removes the selected item from the list.和Renames the selected item in the list.。

   

5. 将以下代码添加到它们的OnExecute处理程序中：

   procedure TForm1.aDeleteExecute(Sender: TObject);
   begin
   
     if CheckListBox1.ItemIndex = -1 then
       Exit;
   
     if MessageBox(Handle, 'Do you want to delete the selected item?',
       'Delete', MB_ICONQUESTION or MB_YESNO) <> IDYES then
       Exit;
   
     CheckListBox1.DeleteSelected;
   
   end;
   
   procedure TForm1.aRenameExecute(Sender: TObject);
   var
     S: string;
   begin
   
     if CheckListBox1.ItemIndex = -1 then
       Exit;
   
     S := CheckListBox1.Items[CheckListBox1.ItemIndex];
     if InputQuery('Rename', 'Please enter the new name:', S) then
       CheckListBox1.Items[CheckListBox1.ItemIndex] := S;
   
   end;
   

6. 将以下代码添加到它们的OnUpdate处理程序中：

   procedure TForm1.aDeleteUpdate(Sender: TObject);
   begin
     aDelete.Enabled := CheckListBox1.ItemIndex <> -1;
   end;
   
   procedure TForm1.aRenameUpdate(Sender: TObject);
   begin
     aRename.Enabled := CheckListBox1.ItemIndex <> -1;
   end;
   

7. TPopupMenu在表格上拖一个。命名它pmList。添加两个菜单项。将它们的Action属性分别设置为aDelete和aRename。这将自动为项目提供操作的标题、提示和热键：

   

8. 现在分配pmList给复选框控件的PopupMenu属性。

9. 测试应用程序。请注意，上下文菜单项仅在选择项时才启用；否则，它们都被禁用。（这要归功于OnUpdate处理程序。跳过这些我们会很草率。但请注意，我们仍然会验证是否在OnExceute处理程序中选择了一个项目。在质量软件中，您总是同时使用皮带和支架。）

   

10. 当然，我们必须将Del和F2键映射到删除和重命名操作。我们可以使用ShortCut动作的属性，但是即使另一个 GUI 控件具有焦点，这也会使这些键在此列表中删除和重命名，这是非常糟糕的。相反，我们OnKeyDown向复选框控件本身添加了一个处理程序：

    procedure TForm1.CheckListBox1KeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    begin
      case Key of
        VK_DELETE:
          aDelete.Execute;
        VK_F2:
          aRename.Execute;
      end;
    end;