Perl,fork,信号量,进程

Question

我需要创建一个程序,从列表中以随机顺序同时运行3个进程,并逐个锁定这些进程,以避免重复.例如,您有3个程序的列表:

@array = ( 1,2,3);

1. perl script.pl最初运行2;
2. 通过随机尝试再次运行2并收到错误(因为2现在已被信号量锁定).
3. 运行1.
4. 运行3.
5. script.pl等待所有1,2,3结束工作,然后退出自己.

到目前为止,这是我的代码:

#!/usr/bin/perl -w
use IPC::SysV qw(IPC_PRIVATE S_IRUSR S_IWUSR IPC_CREAT);
use IPC::Semaphore;
use Carp ();

print "Program started\n";

sub sem {
    #semaphore lock code here
  }

sub chooseProgram{
    #initialise;
    my $program1 = "./program1.pl";
    my $program2 = "./program2.pl";
    my $program3 = "./program3.pl";
    my $ls = "ls";
    my @programs = ( $ls, $program1, $program2, $program3 );    

    my $random = $programs[int rand($#programs+1)];
    print $random."\n";
    return $random;
}

#parent should fork child;
#child should run random processes;
#avoid process clones with semaphore;
sub main{                   
    my $pid = fork();
    if ($pid){
        #parent here
    }
    elsif (defined($pid)){
        #child here     
        print "$$ Child started:\n";
        #simple cycle to launch and lock programs
        for (my $i = 0; $i<10; $i++){
            # semLock(system(chooseProgram()); #run in new terminal window
            # so launched programs are locked and cannot be launched again
        }
    }
    else {
        die("Cannot fork: $!\n");
    } 
    waitpid($pid, 0);
    my $status = $?;
    #print $status."\n";
}
main();
exit 0;

问题:

1. 需要锁定文件; (我不知道如何使用信号量.一些锁定文件的尝试失败,因此排除了该代码.)
2. 孩子等到第一个节目在第二次开始前结束.如何与一个孩子同时开始三个项目？(是否可以或应该为一个程序创建一个孩子？).
3. 程序是非gui,应该在终端运行.如何在新的终端窗口(选项卡)中运行程序？
4. 没有正确检查是否所有@programs程序都已启动. - 不太重要.

Answer 1

您的随机性要求非常奇怪，但如果我正确理解您的要求，那么您不需要任何类型的锁定来执行您想要的操作。（所以1)你的问题消失了）

首先打乱程序数组，然后启动该打乱数组的每个命令（这涉及您的4)）。然后只有在你开始一切waitpid 之后（涉及你的2)）。

下面的代码就是这样做的，sleep在新终端中启动各种实例（我使用urxvt, 根据您想要生成的终端进行调整 - 这涉及您的3)）。

#! /usr/bin/perl -w
use strict;
use warnings;

my @progs = ("urxvt -e sleep 5", "urxvt -e sleep 2", "urxvt -e sleep 1");
my @sgrop;
my @pids;

# Shuffle the programs
while (my $cnt = scalar(@progs)) {
    push @sgrop, splice @progs, int(rand($cnt)), 1;
}

# Start the progs
foreach my $prog (@sgrop) {
    my $pid = fork();
    if (!$pid) {
        exec($prog);
        # exec does not return
    } else {
        print "Started '$prog' with pid $pid\n";
        push @pids, $pid;
    }
}

# Wait for them
map {
    waitpid($_, 0);
    print "$_ done!\n";
} (@pids);

不确定洗牌是否是最好的，但它确实有效。其背后的想法只是从初始（已排序）列表中随机选择一个元素，将其从那里删除并将其添加到已打乱的列表中。重复直到初始列表为空。

如果您试图在系统范围内锁定程序（即系统中没有其他进程应该能够启动它们），那么我很抱歉，但这是不可能的，除非程序保护自己免受并发执行。

如果您的问题是关于信号量的，那么很抱歉我错过了您的观点。IPC 文档有相关的示例代码。我真的认为没有必要为了你想要做的事情而变得那么复杂。

为了方便起见，您可以按照以下方式使用该模块进行操作IPC::Semaphore。

在主程序开始时，创建一个信号量集，其中包含所需数量的信号量：

use IPC::SysV qw(S_IRUSR S_IWUSR IPC_CREAT IPC_NOWAIT);
use IPC::Semaphore;

my $numprocs = scalar(@progs);
my $sem = IPC::Semaphore->new(1234, # this random number is the semaphore key. Use something else
    $numprocs,                      # number of semaphores you want under that key
    S_IRUSR | S_IWUSR | IPC_CREAT);

检查是否有错误，然后将所有信号量初始化为 1。

$sem->setall( (1) x $numprocs) || die "can't set sems $!";

在启动进程的代码中，在开始之前（尽管在分叉之后），尝试获取信号量：

if ($sem->op($proc_number, -1, IPC_NOWAIT)) {
  # here, you got the semaphore - so nothing else is running this program
  # run the code
  # and once the code is done:
  $sem->op($proc_number, 1, 0); # release the semaphore
  exit(0);
} else {
  # someone else is running this program already
  exit(1); # or something
}

在上面，$proc_number每个程序必须是唯一的（例如，它可能是程序数组中的索引）。不要exec用来启动程序。system例如使用。

请注意，在这种情况下，您将必须处理子进程的退出代码。如果退出代码为零，您可以将该程序标记为已运行。如果没有，您需要重试。（这会变得混乱，你需要跟踪哪个程序运行或没有运行。我建议使用程序编号（$proc_number）的哈希值来存储它是否已经完成，以及当前正在运行的 pid （或尝试运行）该代码。您可以使用该哈希来找出仍需要执行哪些程序。）

最后，当一切都完成并且你已经等待了所有的孩子之后，你应该自己清理：

$sem->remove;

该代码缺乏适当的错误检查，如果清理没有正确完成（即代码启动时信号量已经存在），则会奇怪地工作（即根本不好）。但它应该让你开始。