除了 as-pattern，@ 在 Haskell 中还有什么意思？

Question

我目前正在研究 Haskell 并尝试了解一个使用 Haskell 来实现加密算法的项目。在线阅读Learn You a Haskell for Great Good 后，我开始了解该项目中的代码。然后我发现我被困在以下带有“@”符号的代码中：

-- | Generate an @n@-dimensional secret key over @rq@.
genKey :: forall rq rnd n . (MonadRandom rnd, Random rq, Reflects n Int)
       => rnd (PRFKey n rq)
genKey = fmap Key $ randomMtx 1 $ value @n

这里的 randomMtx 定义如下：

-- | A random matrix having a given number of rows and columns.
randomMtx :: (MonadRandom rnd, Random a) => Int -> Int -> rnd (Matrix a)
randomMtx r c = M.fromList r c <$> replicateM (r*c) getRandom

而 PRFKey 定义如下：

-- | A PRF secret key of dimension @n@ over ring @a@.
newtype PRFKey n a = Key { key :: Matrix a }

我能找到的所有信息来源都说 @ 是 as-pattern，但是这段代码显然不是这种情况。我在https://www.haskell.org/definition/haskell2010.pdf 上查看了在线教程、博客甚至Haskell 2010 语言报告。这个问题根本没有答案。

在这个项目中也可以通过这种方式使用@ 找到更多代码片段：

-- | Generate public parameters (\( \mathbf{A}_0 \) and \(
-- \mathbf{A}_1 \)) for @n@-dimensional secret keys over a ring @rq@
-- for gadget indicated by @gad@.
genParams :: forall gad rq rnd n .
            (MonadRandom rnd, Random rq, Reflects n Int, Gadget gad rq)
          => rnd (PRFParams n gad rq)
genParams = let len = length $ gadget @gad @rq
                n   = value @n
            in Params <$> (randomMtx n (n*len)) <*> (randomMtx n (n*len))

我非常感谢对此的任何帮助。

Answer 1

那 @n是现代 Haskell 的一个高级功能，通常 LYAH 之类的教程不会涵盖它，报告中也找不到。

它被称为类型应用程序，是一种 GHC 语言扩展。要理解它，请考虑这个简单的多态函数

dup :: forall a . a -> (a, a)
dup x = (x, x)

直观的调用dup工作如下：

• 所述呼叫者选择一个类型 a
• 所述呼叫者选择一个值 x的先前选择的类型的a
• dup 然后用类型值回答 (a,a)

从某种意义上说，dup它有两个参数：类型a和值x :: a。然而，GHC 通常能够推断出类型a（例如从x，或从我们使用的上下文dup），所以我们通常只传递一个参数给dup，即x。例如，我们有

dup True    :: (Bool, Bool)
dup "hello" :: (String, String)
...

现在，如果我们想a显式传递怎么办？那么，在这种情况下，我们可以打开TypeApplications扩展，然后写

dup @Bool True      :: (Bool, Bool)
dup @String "hello" :: (String, String)
...

注意@...携带类型（不是值）的参数。这些是在编译时存在的东西，只是 - 在运行时参数不存在。

我们为什么要那样？好吧，有时x周围没有，我们想刺激编译器选择正确的a. 例如

dup @Bool   :: Bool -> (Bool, Bool)
dup @String :: String -> (String, String)
...

类型应用程序通常与其他一些扩展结合使用，这些扩展使 GHC 无法进行类型推断，例如模棱两可的类型或类型系列。我不会讨论这些，但您可以简单地理解，有时您确实需要帮助编译器，尤其是在使用强大的类型级功能时。

现在，关于你的具体情况。我没有所有的细节，我不知道图书馆，但很可能你在类型级别n代表了一种自然数值。在这里，我们是相当先进的扩展跳水，像上面提到的那些加，也许，有些类型类机械。虽然我不能解释一切，但希望我能提供一些基本的见解。直觉上，DataKindsGADTs

foo :: forall n . some type using n

将作为参数@n，一种编译时自然的，不会在运行时传递。反而，

foo :: forall n . C n => some type using n

采用@n（编译时），具有共同的证明是n，满足约束C n。后者是一个运行时参数，它可能会暴露 的实际值n。事实上，在你的情况下，我猜你有一些模糊的相似之处

value :: forall n . Reflects n Int => Int

这基本上允许代码将类型级别自然带入术语级别，基本上将“类型”作为“值”访问。（顺便说一下，上面的类型被认为是“模棱两可”的——你真的需要@n消除歧义。）

最后：n如果我们稍后将其转换为术语级别，为什么要在类型级别传递？简单地写出像这样的函数不会更容易

foo :: Int -> ...
foo n ... = ... use n

而不是更麻烦

foo :: forall n . Reflects n Int => ...
foo ... = ... use (value @n)

诚实的回答是：是的，这会更容易。但是，n类型级别允许编译器执行更多的静态检查。例如，您可能想要一个类型来表示“整数模n”，并允许添加这些。拥有

data Mod = Mod Int  -- Int modulo some n

foo :: Int -> Mod -> Mod -> Mod
foo n (Mod x) (Mod y) = Mod ((x+y) `mod` n)

有效，但没有检查x和y是否具有相同的模数。如果我们不小心的话，我们可能会加苹果和橙子。我们可以改写

data Mod n = Mod Int  -- Int modulo n

foo :: Int -> Mod n -> Mod n -> Mod n
foo n (Mod x) (Mod y) = Mod ((x+y) `mod` n)

这是更好的，但仍然允许调用，foo 5 x y即使n不是5。不好。反而，

data Mod n = Mod Int  -- Int modulo n

-- a lot of type machinery omitted here

foo :: forall n . SomeConstraint n => Mod n -> Mod n -> Mod n
foo (Mod x) (Mod y) = Mod ((x+y) `mod` (value @n))

防止事情出错。编译器静态检查所有内容。代码更难使用，是的，但从某种意义上说，让它更难使用是重点：我们想让用户无法尝试添加错误的模数。

结论：这些是非常高级的扩展。如果您是初学者，则需要慢慢地学习这些技术。如果您在短期学习后仍无法掌握它们，请不要气馁，这确实需要一些时间。一次一小步，为每个功能解决一些练习，以了解它的要点。当您遇到困难时，您将始终拥有 StackOverflow :-)