Terraform 在 zip 准备好之前创建 lambda

Question

我正在尝试创建一个 Terraform 模块来构建我的 JS lambda，压缩并部署它们。然而这被证明是有问题的

resource "null_resource" "build_lambda" {
  count = length(var.lambdas)

  provisioner "local-exec" {
    command = "mkdir tmp"
    working_dir = path.root
  }

  provisioner "local-exec" {
    command = var.lambdas[count.index].code.build_command
    working_dir = var.lambdas[count.index].code.working_dir
  }
}

data "archive_file" "lambda_zip" {
  count = length(var.lambdas)
  type        = "zip"
  source_dir = var.lambdas[count.index].code.working_dir
  output_path = "${path.root}/tmp/${count.index}.zip"

  depends_on = [
    null_resource.build_lambda
  ]
}

/*******************************************************
* Lambda definition
*******************************************************/
resource "aws_lambda_function" "lambda" {
  count = length(var.lambdas)
  filename = data.archive_file.lambda_zip[count.index].output_path
  source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)
  function_name = "${var.application_name}-${var.lambdas[count.index].name}"
  description = var.lambdas[count.index].description

  handler = var.lambdas[count.index].handler
  runtime = var.lambdas[count.index].runtime
  role = aws_iam_role.iam_for_lambda.arn
  memory_size = var.lambdas[count.index].memory_size

  depends_on = [aws_iam_role_policy_attachment.lambda_logs, aws_cloudwatch_log_group.log_group, data.archive_file.lambda_zip]
}

该属性source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)虽然在技术上不是强制性的，但却是必要的，否则现有的 lambda 永远不会被覆盖，因为 Terraform 会认为它仍然是相同版本的 lambda 并且将完全跳过部署。不幸的是，看起来 filebase64sha256 方法是在创建任何资源之前评估的。这意味着没有用于哈希计算的 zip，因此我收到错误

Error: Error in function call

  on modules\api-gateway-lambda\main.tf line 35, in resource "aws_lambda_function" "lambda":
  35:   source_code_hash = filebase64sha256(data.archive_file.lambda_zip[count.index].output_path)
    |----------------
    | count.index is 0
    | data.archive_file.lambda_zip is tuple with 1 element

Call to function "filebase64sha256" failed: no file exists at tmp\0.zip.

如果我手动将 zip 放在正确的位置，我可以看到整个过程开始工作，并且该 zip 最终会被新的 zip 覆盖，但这种情况下的哈希必须来自前一个 zip。以正确的顺序执行整个事情的正确方法是什么？

Answer 1

数据archive_file源有自己的output_base64sha256属性，可以为您提供相同的结果，而无需要求 Terraform 读取尚不存在的文件：

  source_code_hash = data.archive_file.lambda_zip[count.index].output_base64sha256

数据源将在创建文件的同时填充此文件，并且由于您的 lambda 函数依赖于数据源，因此在评估 lambda 函数配置之前它始终可用。