Python 与 Julia 速度比较

Question

我试着比较这两个片段，看看一秒钟可以完成多少次迭代。事实证明，Julia 实现了 250 万次迭代，而 Python 实现了 400 万次。朱莉娅不是应该更快吗？或者这两个片段可能不等价？

Python：

t1 = time.time()
i = 0
while True:
    i += 1
    if time.time() - t1 >= 1:
        break

朱莉娅：

function f()
    i = 0
    t1 = now()
    while true
        i += 1
        if now() - t1 >= Base.Dates.Millisecond(1000)
            break
        end
    end
    return i
end

Answer 1

这是一种奇怪的性能比较，因为通常会测量计算实质内容所需的时间，而不是查看在一定时间内可以进行多少次琐碎的迭代。我无法让您的 Python 和 Julia 代码正常工作，因此我修改了 Julia 代码以使其正常工作，只是没有运行 Python 代码。正如@chepner 在评论中指出的那样，使用对象now()并进行时间比较DateTime是相当昂贵的。Pythontime.time()函数只返回一个浮点值。事实证明，有一个被称为 Julia 的函数time()执行完全相同的操作：

julia> time()
1.587648091474481e9

这是f()我的系统上原始函数（修改后可以工作）的时间：

julia> using Dates

julia> function f()
           i = 0
           t1 = now()
           while true
               i += 1
               if now() - t1 >= Millisecond(1000)
                   break
               end
           end
           return i
       end
f (generic function with 1 method)

julia> f()
4943739

它在时间结束之前进行了近 500 万次迭代。正如我所说，我无法让您的 Python 代码在我的系统上运行而无需大量摆弄（我没有费心去做）。但这里有一个f()使用time()它的版本，我将富有想象力地称之为g()：

julia> function g()
           i = 0
           t1 = time()
           while true
               i += 1
               if time() - t1 >= 1
                   break
               end
           end
           return i
       end
g (generic function with 1 method)

julia> g()
36087637

这个版本进行了 3600 万次迭代。所以我猜 Julia 的循环速度更快？好极了！嗯，实际上这个循环中的主要工作是调用time()so... Julia 生成大量time()调用的速度更快！

为什么这个时间很奇怪？正如我所说，这里的大部分实际工作都是调用time(). 循环的其余部分并没有真正做任何事情。在优化编译语言中，如果编译器看到一个没有做任何事情的循环，它将完全消除它。例如：

julia> function h()
           t = 0
           for i = 1:100_000_000
               t += i
           end
           return t
       end
h (generic function with 1 method)

julia> h()
5000000050000000

julia> @time h()
  0.000000 seconds
5000000050000000    

哇，零秒！这怎么可能？好吧，让我们看一下LLVM 代码（有点像机器代码，但对于用作中间表示的虚拟机器）这降低为：

julia> @code_llvm h()

;  @ REPL[16]:1 within `h'
define i64 @julia_h_293() {
top:
;  @ REPL[16]:6 within `h'
  ret i64 5000000050000000
}

编译器看到循环，计算出每次的结果都相同，并且只返回该常量值而不是实际执行循环。当然，这需要零时间。

Answer 2

你可能想time_ns在 Julia 中使用函数：

function f()
    i = 0
    t1 = time_ns()
    while true
        i += 1
        if time_ns() - t1 >= 10^9
            break
        end
    end
    return i
end

在我的电脑上，它的运行速度比 Python 快 10 倍。