有没有一种优雅的方式来编写这段代码？

Question

我继承了一些代码,当我看到它时,它让我感到畏缩.是否有更优雅的方式来写下面的内容？

Dim myItem As DTO.MyBaseClass = Nothing
Dim myType As String = GetTypeString()
Select Case myType
  Case Is = "Case1"
    myItem = Bus.BusManager(Of DTO.MyClass1).Read()
  Case Is = "Case2"
    myItem = Bus.BusManager(Of DTO.MyClass2).Read()
'... etc etc for 30 lines

有没有办法从字符串到类类型创建一个映射,然后只有这样的行？或类似的东西？

myItem = Bus.BusManager(Of MappingDealy(myType)).Read()

Answer 1

由于是泛型，因此必须在编译时指定BusManager传入的类型。Of <type>它不像传统参数那样可以在运行时更改。

从您列出的代码中尚不清楚BusManager实际的作用。如果它所做的只是创建泛型类型的实例，那么创建它的人可能并不真正理解泛型。您是否有能力重新设计BusManager其工作方式，或者您仅限于按原样使用它？

正如 @jmoreno 提到的，您可以使用反射从包含类型名称的字符串创建类型的实例。其工作原理如下：

Imports System.Reflection
Imports System.IO

Public Class ObjectFactory
    Private Shared Function CreateObjectFromAssembly(ByVal assembly As Assembly, ByVal typeName As String) As Object
        ' resolve the type
        Dim targetType As Type = assembly.GetType(typeName)
        If targetType Is Nothing Then
            Throw New ArgumentException("Can't load type " + typeName)
        End If

        ' get the default constructor and instantiate
        Dim types(-1) As Type
        Dim info As ConstructorInfo = targetType.GetConstructor(types)
        Dim targetObject As Object = info.Invoke(Nothing)
        If targetObject Is Nothing Then
            Throw New ArgumentException("Can't instantiate type " + typeName)
        End If

        Return targetObject
    End Function

    Public Shared Function CreateObject(ByVal typeName As String) As Object
        Return CreateObjectFromAssembly(Assembly.GetExecutingAssembly, typeName)
    End Function

    Public Shared Function CreateObject(ByVal typeName As String, ByVal assemblyFileName As String) As Object
        Dim assemblyFileInfo = New FileInfo(assemblyFileName)
        If assemblyFileInfo.Exists Then
            Return CreateObjectFromAssembly(Reflection.Assembly.LoadFrom(assemblyFileName), typeName)
        Else
            Throw New ArgumentException(assemblyFileName + " cannot be found.")
        End If
    End Function

End Class

在生产应用程序中，我可能会将所有这些方法的返回类型设置为我的基类或接口。只需确保您传递完整的内容，typeName包括命名空间。

有了该工厂类，代码的优雅版本将如下所示：

Dim myItem as DTO.MyBaseClass = ObjectFactory.CreateObject("DTO." & GetTypeString())