如何将 MOVE 用于以记录为元素且其上有动态数组字段的动态数组？

Question

我正在使用 Delphi Rio，我的程序有很多动态数组操作。为了提高一些长数组复制的速度，我尝试使用 Move 。对于基本类型（实数、整数）的一维动态数组，我可以管理 Move 的使用，但对于以记录作为其元素的动态数组，并且该记录具有另一个动态数组字段，我很难使其工作。我对动态数组记录字段使用 MOVE 的方式，在发出命令后，这些字段继续指向源数组的原始源地址。

测试过程：array_A是动态记录数组，该记录的两个字段都是动态数组。发出 Move(array_A[0],B_array[0],sizeof(Array[0]) * length(arra_A)) 后，然后更改 array_B 动态数组字段中的值，这也会导致 array_A 的值发生变化！两者都指向同一个地址。如何使用 MOVE 更改此行为？

看我的代码：

    program ProjArrayMove;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

Type

     Arrayint   = Tarray<Integer>;
     Arrayreal  = TArray<Real>;

     RECmember = record
           mcode       : integer;
           mname       : string[30];
           mdynarr_int  : arrayint;
           mdynarr_real : arrayreal;
     end;

     ArrayMember = array of RECMember;

     Procedure FillsRecord (var pRec : RECmember; pSize : integer; pFactor : real);
     // Given a pRec , fills each dynamic array fields with pSize numbers
     var
        idx : integer;
     begin
          setlength(pRec.mdynarr_int,pSize);
          setlength(pRec.mdynarr_real,pSize);
          with pRec do
          begin
               for idx := 0 to pSize - 1 do
               begin
                    mdynarr_int[idx]  := idx;
                    mdynarr_real[idx] := idx * (1.0 + pFactor);
               end;
          end;
     end;


     Procedure FillsArray  (var pArr : ArrayMember; pSizeArray, pSizeRec : integer; pChar : Char);
     // Given a array of records pArr  , fills the array with pSizeArray records
     var
        idx : integer;
     begin
           setlength(pArr,pSizeArray);

           //Fils first record - element 0
           FillsRecord(pArr[0],pSizeRec,2.3);
           pArr[0].mcode := 0;
           pArr[0].mname := '0' + pChar;

           //Fills major array with records , each record with dynamic arrays fields also filled
           for idx := 1 to High(pArr) do
           begin
                FillsRecord(pArr[idx],pSizeRec,idx * 2.3);
                pArr[idx].mcode := idx;
                pArr[idx].mname  := idx.ToString + StringOfChar(pChar,2);
           end;
     end;


     Procedure PrintArray(pArr : ArrayMember);
     // Given an array of records pArr, prints each element including the dynami array fields
     var
        i,j : integer;
     begin
           Writeln(stringofchar('=',20));
           for I := Low(pArr) to High(pArr) do
           begin
                 Write('Idx :' + i.ToString + ' ' );
                 Write('Code :' + pArr[i].mcode.ToString  + ' ' );
                 Write('Name :' + pArr[i].mname + '   ');
                 Write(' mdynarr_int :');
                 for j := Low(pArr[i].mdynarr_int) to High(pArr[i].mdynarr_int) do
                     Write(' ' + pArr[i].mdynarr_int[j].ToString);
                 Write(' mdynarr_real :');
                 for j := Low(pArr[i].mdynarr_real) to High(pArr[i].mdynarr_real) do
                     Write(' ' + FloatToStr(pArr[i].mdynarr_real[j]));
                 Writeln;
           end;
     end;

var
    larray_A, larray_B : ArrayMember;
    idx, lsizeA, lsize_int, lsize_real : integer;
begin
      try
          //Step 1 - Fills the first array with 10 records and its relaed dynamic arrays fields with 5 elements each
          FillsArray(larray_A,10,5, 'A');

          //Step 2- An attempt to ast copy elements of larray_A to larray_B
          Setlength(larray_B, length(larray_A));
          lsizeA := Sizeof(larray_A[0]);

          MOVE(larray_A[0], larray_B[0], length(larray_A) * lsizeA);

          Writeln('========== ARRAY A ==========');

          PrintArray(larray_A);
          readln;

          Writeln('========== ARRAY B ==========');

          PrintArray(larray_B);
          readln;

          //Now change values in item of array B
          larray_B[0].mcode := 777;
          larray_B[0].mname := 'B was changed';
          larray_B[0].mdynarr_int[0]  := 427;
          larray_B[0].mdynarr_real[0] := 784.96;

          Writeln('======= ARRAY B AFTER CHANGES ========');

          PrintArray(larray_B);
          readln;

          Writeln('====== VERIFYING IMPACT IN ARRAY A =======');

          PrintArray(larray_A);
          readln;

          //3-Attemp to use MOVE to copy contet of dynamic arrays fields in records member
          lsize_int := Sizeof(larray_A[0].mdynarr_int[0]);
          lsize_real:= Sizeof(larray_A[0].mdynarr_real[0]);

          for idx := Low(larray_B) to High(larray_B) do
          begin
                setlength(larray_B[idx].mdynarr_int,length(larray_A[idx].mdynarr_int));
                **MOVE(larray_A[idx].mdynarr_int[0],larray_B[idx].mdynarr_int[0],
                     lsize_int * length(larray_B[idx].mdynarr_int) );**

                setlength(larray_B[idx].mdynarr_real,length(larray_A[idx].mdynarr_real));
                MOVE(larray_A[idx].mdynarr_int[0],larray_B[idx].mdynarr_int[0],
                     lsize_real * length(larray_B[idx].mdynarr_real) );
          end;

          Writeln;
          Writeln;

          //Now change values in item of array B
          larray_B[0].mcode := 555;
          larray_B[0].mname := '2nd Change in B';
          larray_B[0].mdynarr_int[0]  := 10427;
          larray_B[0].mdynarr_real[0] := 10784.96;

          Writeln('======= ARRAY B AFTER 2nd CHANGES ========');

          PrintArray(larray_B);
          readln;

          Writeln('====== VERIFYING IMPACT IN ARRAY A =======');

          PrintArray(larray_A);
          readln;

          Writeln('==> It seems that MOVE in record fields of dynamic array type does not work as I expected - WHY ?');
          readln;

      except
        on E: Exception do
          Writeln(E.ClassName, ': ', E.Message);
      end;
end.

谢谢你们 ！

Answer 1

您的第一次调用会Move获取内部数组引用的副本，但会在编译器后面执行，因此会中断引用计数。从那时起，你所做的一切都注定会失败。您不能使用Move受管理的数据。

要正确执行此操作，您需要如下代码：

type
  TMyRec = record
    Int: Integer;
    Arr: TArray<Integer>;
    function Clone: TMyRec;
  end;

function TMyRec.Clone: TMyRec;
begin
  Result.Int := Int;
  Result.Arr := Copy(Arr);
end;

function CloneRecArray(const Arr: array of TMyRec): TArray<TMyRec>;
var
  i: Integer;
begin
  SetLength(Result, Length(Arr));
  for i := 0 to High(Result) do
    Result[i] := Arr[i].Clone;
end;