SIMPLE-READER-ERROR ，非法尖锐的宏字符，子字符 #\< 没有为调度字符定义 #\#

Question

在 David B. Lamkins 所著的《Successful Lisp》一书的第 4 章中，有一个简单的应用程序可以跟踪银行支票。

https://dept-info.labri.fr/~strandh/Teaching/MTP/Common/David-Lamkins/chapter04.html

最后，我们编写了一个宏来保存和恢复函数。当我执行 reader 函数并且要读取的值是哈希表时，就会出现问题。

保存和恢复功能的宏是：

(defmacro def-i/o (writer-name reader-name (&rest vars))
  (let ((file-name (gensym))
        (var (gensym))
        (stream (gensym)))
    `(progn
       (defun ,writer-name (,file-name)
         (with-open-file (,stream ,file-name
                                  :direction :output :if-exists :supersede)
           (dolist (,var (list ,@vars))
             (declare (special ,@vars))
             (print ,var ,stream))))
       (defun ,reader-name (,file-name)
         (with-open-file (,stream ,file-name
                                  :direction :input :if-does-not-exist :error)
           (dolist (,var ',vars)
             (set ,var (read ,stream)))))
       t)))

这是我的哈希表以及发生了什么：

    (defvar *payees* (make-hash-table :test #'equal))

    (check-check 100.00 "Acme" "Rocket booster T-1000")

    CL-USER> *payees*
    #<HASH-TABLE :TEST EQUAL :COUNT 0 {25520F91}>

    CL-USER> (check-check 100.00 "Acme" "T-1000 rocket booster")
    #S(CHECK
    :NUMBER 100
    :DATE "2020-4-1"
    :AMOUNT 100.0
    :PAID "Acme"
    :MEMO "T-1000 rocket booster")
    CL-USER> (def-i/o save-checks charge-checks (*payees*))
    T
    CL-USER> (save-checks "/home/checks.dat")
    NIL
    CL-USER> (makunbound '*payees*)
    *PAYEES*

    CL-USER> (load-checks "/home/checks.dat")
; Evaluation aborted on #<SB-INT:SIMPLE-READER-ERROR "illegal sharp macro character: ~S" {258A8541}>.

在 Lispworks 中，错误信息是：

Error: subcharacter #\< not defined for dispatch char #\#.

为了简化，如果我执行，我会得到同样的错误：

CL-USER> (defvar *payees* (make-hash-table :test #'equal)) 
*PAYEES*
CL-USER> (with-open-file (in "/home/checks.dat"
                 :direction :input)
       (set *payees* (read in)))
; Evaluation aborted on #<SB-INT:SIMPLE-READER-ERROR "illegal sharp macro character: ~S" {23E83B91}>.

有人可以向我解释问题的来源，以及我需要在代码中修复什么才能使其正常工作。预先感谢您可以给我的解释和您可以给我的帮助。

Answer 1

无法读回的值用 打印#<，请参阅Sharpsign Less-Than-Sign。Common Lisp 没有定义哈希表应该如何以可读的方式打印（哈希表没有读取器语法）：

* (make-hash-table)
#<HASH-TABLE :TEST EQL :COUNT 0 {1006556E53}>

书中的示例只适合与之前展示的银行示例一起使用，并不打算成为通用的序列化机制。

根据您的需要，有多种方法可以打印哈希表并将其读回，但没有默认表示。有关存储任意对象的库，请参阅cl-store。

自定义dump功能

让我们编写一个评估为等效哈希表的表单；让我们定义一个名为 的泛型函​​数dump，以及一个简单地按原样返回对象的默认方法：

(defgeneric dump (object)
  (:method (object) object))

给定一个哈希表，我们可以将它序列化为plist（列表中键/值元素的序列），同时还调用dump键和值，以防我们的哈希表包含哈希表：

(defun hash-table-plist-dump (hash &aux plist)
  (with-hash-table-iterator (next hash)
    (loop
       (multiple-value-bind (some key value) (next)
         (unless some
           (return plist))
         (push (dump value) plist)
         (push (dump key) plist)))))

相反，重新发明轮子，我们也使用了hash-table-plist从亚历山大系统。

(ql:quickload :alexandria)

以上相当于：

(defun hash-table-plist-dump (hash)
  (mapcar #'dump (alexandria:hash-table-plist hash)))

然后，我们可以专门dump研究哈希表：

(defmethod dump ((hash hash-table))
  (loop
     for (initarg accessor) 
     in '((:test hash-table-test)
          (:size hash-table-size)
          (:rehash-size hash-table-rehash-size)
          (:rehash-threshold hash-table-rehash-threshold))
     collect initarg into args
     collect `(quote ,(funcall accessor hash)) into args
     finally (return
               (alexandria:with-gensyms (h k v)
                 `(loop
                     :with ,h := (make-hash-table ,@args)
                     :for (,k ,v)
                     :on (list ,@(hash-table-plist-dump hash))
                     :by #'cddr
                     :do (setf (gethash ,k ,h) ,v)
                     :finally (return ,h))))))

循环的第一部分计算所有哈希表属性，例如要使用的哈希函数类型或重新哈希大小，并构建具有相同值args的调用的参数列表make-hash-table。

在finally子句中，我们构建了一个loop表达式（参见反引号），它首先分配哈希表，然后根据哈希的当前值填充它，最后返回新的哈希。请注意，生成的代码不依赖于alexandria，它可以从另一个没有这种依赖关系的 Lisp 系统读回。

例子

CL-USER> (alexandria:plist-hash-table '("abc" 0 "def" 1 "ghi" 2 "jkl" 3)
                 :test #'equal)

#<HASH-TABLE :TEST EQUAL :COUNT 4 {100C91F8C3}>

转储它：

CL-USER> (dump *)
(LOOP :WITH #:H603 := (MAKE-HASH-TABLE :TEST 'EQUAL :SIZE '14 :REHASH-SIZE '1.5
                                       :REHASH-THRESHOLD '1.0)
      :FOR (#:K604 #:V605) :ON (LIST "jkl" 3 "ghi" 2 "def" 1 "abc"
                                     0) :BY #'CDDR
      :DO (SETF (GETHASH #:K604 #:H603) #:V605)
      :FINALLY (RETURN #:H603))

生成的数据也是有效的 Lisp 代码，评估它：

CL-USER> (eval *)
#<HASH-TABLE :TEST EQUAL :COUNT 4 {100CD5CE93}>

结果哈希是equalp原始哈希：

CL-USER> (equalp * ***)
T