ARM 调用约定是否允许函数不将 LR 存储到堆栈？

Question

正如标题所说，我在理解 ARM 架构的调用约定时遇到了问题。特别是，当你调用一个子程序时，我仍然很难知道 LR 寄存器会发生什么。

我认为当你进入一个子程序时处理 LR 寄存器的最明显和更安全的方法是将它存储到堆栈中，但这种行为没有出现在文档中，所以我想到了下面的例子。

我将用 C 语言编写它，因为我认为用 C 语言更容易解释。想象一下你只有两个函数

void function_1(void){
   //some code here
}

void function_2(void){
   //some code here
   function_1();
   //some code here
}

我在里面使用 LR 寄存器的function_1方式就像我之前说的那样，我将它的值存储在堆栈中，但如果你看得更近，function_1 不会调用任何其他子例程，因此这是不必要的。

是否有可能在使用 ARM 编译器时，该编译器会决定不将 LR 存储到堆栈中？

我在此信息中心网站上阅读了有关呼叫标准的信息

Answer 1

调用约定只定义了哪些寄存器是调用保留的，哪些是调用破坏的，以及在哪里可以找到堆栈参数。

100% 取决于函数如何确保其返回地址在准备返回时在某处可用。处理这个问题的最简单有效的方法是将它一直留在 LR 中，在叶函数中。（一个不调用其他函数的函数：它是调用图/树中的一片叶子）。

实践中的编译器通常只会将它留在 LR 中的叶函数中，即使禁用了优化。例如，GCC 设置了一个禁用优化的帧指针，但是当它知道它不需要那么多想要使用 LR 的临时寄存器时，它仍然不会存储/重新加载 LR。

否则在非叶函数中，普通编译器通常会将其存储到堆栈中，但如果他们愿意，他们可以例如将 R4 保存到堆栈中mov r4, lr，然后在准备返回时恢复 LR 并重新加载 R4。

理论上，非租用/非线程安全函数可以将其返回地址保存在静态存储中，如果它愿意的话。

Godbolt 的-O2 -mapcs-frame源代码和GCC8.2输出，强制它生成 APCS（ARM 过程调用标准）堆栈帧，即使不需要它。（看起来它与-fno-omit-frame-pointer默认情况下通过优化具有相似的效果。）

void function_1(void){
   //some code here
}

function_1:
    bx      lr     @ with or without -mapcs-frame

void unknown_func(void);   // not visible to the compiler; can't inline
void function_2(void){
   function_1();   // inlined, or IPA optimized as pure and not needing to be called.
   unknown_func(); // tailcall
   unknown_func();
}

function_2:              @@ Without -macps-frame
    push    {r4, lr}         @ save LR like you expected
    bl      unknown_func
    pop     {r4, lr}         @ around a call
    b       unknown_func     @ but then tailcall for the 2nd call.

或使用 APCS：

    mov     ip, sp
    push    {fp, ip, lr, pc}
    sub     fp, ip, #4
    bl      unknown_func
    sub     sp, fp, #12
    ldm     sp, {fp, sp, lr}
    b       unknown_func

int func3(void){
    unknown_func();
    return 1;               // prevent tailcall
}

func3:           @@ Without -macps-frame
    push    {r4, lr}
    bl      unknown_func
    mov     r0, #1
    pop     {r4, pc}

或使用 APCS：

func3:
    mov     ip, sp
    push    {fp, ip, lr, pc}
    sub     fp, ip, #4
    bl      unknown_func
    mov     r0, #1
    ldmfd   sp, {fp, sp, pc}

由于不需要拇指交互（使用默认编译选项），GCC 会将保存的 LR 弹出到 PC 中，而不是仅返回到 LR 中bx lr。

将 R4 与 LR 一起压入可使堆栈按 8 对齐，这是 IIRC 的默认值。