从坐标列表中提取运动数据

Question

我有一系列带时间戳坐标的CSV文件(X,Y和Z,单位为mm).从中提取运动数据的最简单方法是什么？

衡量标准

我想提取的信息包括以下内容:

1. 方向变化的数量
2. 第一次和最后一次运动的初始加速度
3. ......以及这些运动的方位(角度)
4. 非平稳时的平均速度

理想情况下,我最终希望能够对运动模式进行分类,因此任何能够提出这种方式的人都可以获得奖励积分.令我感到震惊的是,我能做到这一点的一种方法是从坐标生成动画的图片/视频,并要求人们对它们进行分类 - 关于我如何做到这一点的建议非常受欢迎.

噪声

一个复杂因素是读数受到噪音的污染.为了克服这个问题,每个记录都以至少20秒的静止为前提,这可以作为一种"噪声分布".我不知道如何实现这一点.

细节

如果它有帮助,则记录的动作是在简单的抓取任务期间的人手的动作.使用连接到手腕的磁性运动跟踪器生成数据.另外,我正在使用C#,但我猜数学与语言无关.

编辑

• 磁跟踪器规格:http://www.ascension-tech.com/realtime/RTminiBIRD500_800.php
• 示例数据文件:http://tdwright.co.uk/sample.csv

赏金

对于赏金,我真的很想看到一些(伪)代码示例.

Answer 1

让我们看看您的示例数据可以做些什么.

免责声明:我没有阅读您的硬件规格(tl; dr :))

为方便起见,我会在Mathematica中解决这个问题.相关算法(不多)将作为链接提供.

第一个观察是所有测量的时间间隔相等,这对于简化方法和算法最为方便.我们将在方便时代表"时间"或"滴答"(测量),因为它们是等价的.

让我们首先按轴绘制您的位置,看看问题是什么:

(* This is Mathematica code, don't mind, I am posting this only for 
   future reference *)
ListPlot[Transpose@(Take[p1[[All, 2 ;; 4]]][[1 ;;]]), 
 PlotRange -> All,
 AxesLabel -> {Style["Ticks", Medium, Bold], 
               Style["Position (X,Y,Z)", Medium, Bold]}]

现在,有两点意见:

• 你的动作开始于1000左右
• 您的行动不会从{0,0,0}开始

因此,我们将略微转换您的数据减去零位置并从950开始.

ListLinePlot[
 Drop[Transpose@(x - Array[Mean@(x[[1 ;; 1000]]) &, Length@x]), {}, 950], 
 PlotRange -> All,
 AxesLabel -> {Style["Ticks", Medium, Bold], 
               Style["Position (X,Y,Z)", Medium, Bold]}]

由于曲线有足够的噪声来破坏计算,我们将使用高斯内核对其进行去噪处理:

kern = Table[Exp[-n^2/100]/Sqrt[2. Pi], {n, -10, 10}];
t = Take[p1[[All, 1]]];
x = Take[p1[[All, 2 ;; 4]]];

x1 = ListConvolve[kern, #] & /@ 
   Drop[Transpose@(x - Array[Mean@(x[[1 ;; 1000]]) &, Length@x]), {}, 
    950];

所以你可以在下面看到原始和平滑的轨迹:

现在我们已准备好将衍生物用于速度和加速度.我们将使用四阶近似值作为一阶和二阶导数.我们也将使用高斯内核平滑它们,如前所述:

Vel = ListConvolve[kern, #] & /@ 
   Transpose@
    Table[Table[(-x1[[axis, i + 2]] + x1[[axis, i - 2]] - 
         8 x1[[axis, i - 1]] + 
         8 x1[[axis, i + 1]])/(12 (t[[i + 1]] - t[[i]])), {axis, 1, 3}], 
    {i, 3, Length[x1[[1]]] - 2}];

Acc = ListConvolve[kern, #] & /@ 
   Transpose@
    Table[Table[(-x1[[axis, i + 2]] - x1[[axis, i - 2]] + 
         16 x1[[axis, i - 1]] + 16 x1[[axis, i + 1]] - 
         30 x1[[axis, i]])/(12 (t[[i + 1]] - t[[i]])^2), {axis, 1,  3}], 
   {i, 3, Length[x1[[1]]] - 2}];

我们绘制它们:

Show[ListLinePlot[Vel,PlotRange->All,
     AxesLabel->{Style["Ticks",Medium,Bold],
                 Style["Velocity (X,Y,Z)",Medium,Bold]}],
    ListPlot[Vel,PlotRange->All]]

Show[ListLinePlot[Acc,PlotRange->All,
     AxesLabel->{Style["Ticks",Medium,Bold],
                 Style["Acceleation (X,Y,Z)",Medium,Bold]}],
     ListPlot[Acc,PlotRange->All]]

现在,我们还有速度和加速度模数:

ListLinePlot[Norm /@ (Transpose@Vel), 
 AxesLabel -> {Style["Ticks", Medium, Bold], 
               Style["Speed Module", Medium, Bold]}, 
 Filling -> Axis]
ListLinePlot[Norm /@ (Transpose@Acc), 
 AxesLabel -> {Style["Ticks", Medium, Bold], 
               Style["Acceleration Module", Medium, Bold]},
 Filling -> Axis]       

和标题,作为速度的方向:

Show[Graphics3D[
 {Line@(Normalize/@(Transpose@Vel)),
 Opacity[.7],Sphere[{0,0,0},.7]},
 Epilog->Inset[Framed[Style["Heading",20],
        Background->LightYellow],{Right,Bottom},{Right,Bottom}]]]

我认为这足以让你入门.如果您在计算特定参数时需要帮助,请告诉我.

HTH!

编辑

举个例子,假设您想要计算手不休息时的平均速度.所以,我们选择速度超过截止值的所有点,例如5,并计算平均值:

Mean@Select[Norm /@ (Transpose@Vel), # > 5 &]
-> 148.085

这个数量的单位取决于你的时间单位,但我没有在任何地方看到它们.

请注意,截止速度不是"直观".您可以通过绘制平均速度与截止速度来搜索适当的值:

ListLinePlot[
 Table[Mean@Select[Norm /@ (Transpose@Vel), # > h &], {h, 1, 30}], 
 AxesLabel -> {Style["Cutoff Speed", Medium, Bold], 
               Style["Mean Speed", Medium, Bold]}]

所以你看到5是一个合适的值.