Terraform：使用 for_each 创建多个实例

Question

我很想在 Terraform 的 count/for_each 函数方面得到一些帮助。

目标是将多个 json 文件（当前两个）读入映射列表，并使用特定命名约定创建特定数量的 aws_instances。

配置

cat test_service_1.json
{
      "instance_name": "front",
      "instance_count": "3",
      "instance_type": "t2.micro",
      "subnet_type": "private",
      "elb": "yes",
      "data_volume": ["no", "0"]
}

cat test_service_2.json
{
      "instance_name": "back",
      "instance_count": "3",
      "instance_type": "t2.micro",
      "subnet_type": "private",
      "elb": "yes",
      "data_volume": ["no", "0"]
}

cat main.tf
locals {
  services = [jsondecode(file("${path.module}/test_service_1.json")),
  jsondecode(file("${path.module}/test_service_2.json"))]
}

resource "aws_instance" "test_instance" {
  ami           = "amzn-ami-hvm-2018.03.0.20200206.0-x86_64-gp2"
  instance_type = "t2.micro"
  tags = merge(
    map("Name", "prod-app-?"),
    map("env", "prod")
  )
}

最终我希望代码遍历两个 json 文件并创建：

prod-front-1
prod-front-2
prod-front-3
prod-back-1
prod-back-2
prod-back-3

我可以用 [count.index +1] 做到这一点，但我不知道如何遍历不止一张地图。

Answer 1

使用资源时，for_each我们的任务始终是编写一个表达式来生成一个映射，其中每个实例有一个我们想要创建的元素。在这种情况下，这似乎是一个表达式，可以将包含计数的单个对象扩展为计数中给定数字的多个对象。

我们可以在 Terraform 中使用的构建块是：

• for表达式将一个集合值投影到另一个集合中。
• 该range函数生成给予一个计数整数的序列。
• 该flatten功能可将多个嵌套列表到一个单一的平面列表。

让我们一步一步来。我们将从您现有的表达式开始从 JSON 文件加载数据：

locals {
  services = [
    jsondecode(file("${path.module}/test_service_1.json")),
    jsondecode(file("${path.module}/test_service_2.json")),
  ]
}

此表达式的结果是一个对象列表，每个文件一个。接下来，我们将这些对象中的每一个扩展为一个对象列表，其长度在 中给出instance_count：

locals {
  service_instance_groups = [
    for svc in local.services : [
      for i in range(1, svc.instance_count+1) : {
        instance_name = "${svc.instance_name}-${i}"
        instance_type = svc.instance_type
        subnet_type   = svc.subnet_type
        elb           = svc.elb
        data_volume   = svc.data_volume
      }
    ]
  ]
}

这个结果是一个对象列表的列表，instance_name由于将值连接i到末尾，每个对象都将具有唯一的值。

要使用for_each，我们需要一个每个实例一个元素的平面集合，因此我们将使用该flatten函数来实现这一点：

locals {
  service_instances = flatten(local.service_instance_groups)
}

现在我们又得到了一个对象列表，但有六个元素（两个输入对象中的每个对象三个）而不是两个。

最后，我们需要将该列表投影为一个地图，其键是 Terraform 用于跟踪实例的唯一标识符。我通常更喜欢直接在for_each参数内部执行这最后一步，因为此结果特定于该用例，并且不太可能在模块中的其他任何地方使用：

resource "aws_instance" "test_instance" {
  for_each = {
    for inst in local.service_instances : inst.instance_name => inst
  }

  ami           = "amzn-ami-hvm-2018.03.0.20200206.0-x86_64-gp2"
  instance_type = each.value.instance_type
  tags = {
    Name = "prod-app-${each.key}"
    Env  = "prod"
  }
}

这应该会导致 Terraform 计划创建具有类似地址的实例aws_instance.test_instance["front-2"]。

我分别写出了上述每个步骤以解释每个步骤的实现，但实际上我通常在一个表达式中同时执行service_instance_groups和service_instances步骤，因为该中间service_instance_groups结果不太可能在其他地方重用。将所有这些整合到一个示例中，然后：

locals {
  services = [
    jsondecode(file("${path.module}/test_service_1.json")),
    jsondecode(file("${path.module}/test_service_2.json")),
  ]
  service_instances = flatten([
    for svc in local.services : [
      for i in range(1, svc.instance_count+1) : {
        instance_name = "${svc.instance_name}-${i}"
        instance_type = svc.instance_type
        subnet_type   = svc.subnet_type
        elb           = svc.elb
        data_volume   = svc.data_volume
      }
    ]
  ])
}

resource "aws_instance" "test_instance" {
  for_each = {
    for inst in local.service_instances : inst.instance_name => inst
  }

  ami           = "amzn-ami-hvm-2018.03.0.20200206.0-x86_64-gp2"
  instance_type = each.value.instance_type
  tags = {
    Name = "prod-app-${each.key}"
    Env  = "prod"
  }
}

作为奖励，除了您在这里询问的内容之外，如果您为这些 JSON 文件提供系统名称并将它们组合到一个子目录中，那么您可以使用Terraform 的fileset功能来自动获取稍后添加到该目录中的任何新文件，而无需更改地形配置。例如：

locals {
  services = [
    for fn in fileset("${path.module}", "services/*.json") :
    jsondecode(file("${path.module}/${fn}"))
  ]
}

以上将生成一个列表，其中包含services子目录中名称以.json.