如何在TVarRec中设置字符串(或AnsiString)常量？

Question

我想将格式化参数传递Args给Format函数.我找到了一些例子,但是我无法找到如何在TVarRec成员中分配字符串常量.以下代码在编译时失败E2089 Invalid typecast.

procedure TForm1.Button1Click(Sender: TObject);
var Arguments: array of TVarRec;
begin
  SetLength(Arguments, 2);

  Arguments[0].VInteger := 111;
  Arguments[1].VAnsiString :=  PAnsiString('Text'); // I want to set this member

  ShowMessage(Format('Decimal: %d, String: %s', Arguments));
end;

任何人都可以建议我如何将字符串(或AnsiString)常量设置为TVarRec成员？我正在使用Delphi 2009.

非常感谢

Answer 1

这似乎适用于XE:

var
  Args: array[0..1] of TVarRec;
  S: AnsiString;
  U: UnicodeString;
begin
  S := 'Hello';
  U := 'world';
  Args[0].VType := vtAnsiString;
  Args[0].VAnsiString := Pointer(S);
  Args[1].VType := vtUnicodeString;
  Args[1].VUnicodeString := Pointer(U);

  Writeln(Format('%s, %s!', Args));
end;

Answer 2

只是我的两分钱.TOndrej的回答是正确的,但我只是想强调一些观点.评论并不是一个好地方.

请注意,AnsiString必须在所有时间TVarRec内使用必须参考.

例如,如果您编写一个设置数组的函数TVarRec,则应确保AnsiString将函数中创建的临时副本创建为变量,该变量将一直保留到TVarRec使用该数组的所有时间.否则,您可能会有一些随机访问冲突(不是每次都有,但只有当MM重新分配ansistring内存时).

例如,以下代码不正确:

type
  TVarRec2 = array[0..1] of TVarRec;

procedure SetVarRec(a,b: integer; var Result: TVarRec2);
begin
  Result[0].VType := vtAnsiString;
  Result[0].VString := pointer(AnsiString(IntToStr(a)));
  Result[1].VType := vtUnicodeString;
  Result[1].VString := pointer(UnicodeString(IntToStr(b)));
end;

因为当过程结束时将释放AnsiString和UnicodeString临时变量,并且Results[].VString仍将指向那些释放的内存......

使用带有一些临时私有字符串的类或记录可能会起到作用:

type
  TMyVar2 = record
  private
    tmpA: AnsiString;
    tmpB: UnicodeString; 
  public
    VarRec: TVarRec2;
    procedure SetVarRec(a,b: integer);
  end;

procedure TMyVar2.SetVarRec(a,b: integer);
begin
  VarRec[0].VType := vtAnsiString;
  tmpA := AnsiString(IntToStr(a));
  VarRec[0].VString := pointer(tmpA);
  VarRec[1].VType := vtUnicodeString;
  tmpB := UnicodeString(IntToStr(b));
  VarRec[1].VString := pointer(tmpB);
end;

当然,在你的程序中,你可能已经有了一个类.在这种情况下,您最好使用方法和一些私有临时字符串.对于多线程安全(即重入)的方法,您应该提供临时字符串作为参数...

我使用这个技巧来获得一个TVarData包含AnsiString类中某些内容的动态数组.事实上,TVarData和 TVarRec既使用这种非引用的指针串,它可能会造成混淆.

请注意,涉及pointer(S)类似陈述的问题可能难以跟踪.