如何在 Haskell 中对这种递归结构进行建模？

Question

我正在尝试通过 Haskell 类型系统对 kdb/q“原子和列表”进行建模。

在 kdb/q 中，所有数据都是由原子构建的。原子是特定数据类型的不可约值。Int、boolean 和 char 是原子的例子。列表是从原子构建的有序集合。由于 q 是一种向量语言，大多数内置操作都是原子的，因此它会递归到参数结构中，直到到达原子。

例如：

(1;2;3) 是一个简单的整数列表 1, 2, 3

(1.0;2;(3;4;5)) 是 1.0(float), 2(int) 的一般列表，以及简单的 int 列表 (3;4;5)

neg 是一个否定一个数字的函数。例如：

负 1 产生 -1

负 -1.0 产生 1f

负 (1.0;2;(3;4;5)) 产生 (-1f;-2;(-3;-4;-5))。

这就是激励我尝试在 Haskell 类型中模拟这种行为的原因。数据类型应该由原子类型和一个列表组成。

以下是我目前所拥有的简化版本。我还进一步尝试使其成为可折叠和可遍历的实例。

data Atom = I Int
          | C Char
          | D Double 
          deriving Show

data Q a = QAtom a 
         | QList [Q a]
         deriving Show

instance Functor Q where
    fmap f (QAtom a) = QAtom (f a)
    fmap f (QList qs) = QList $ fmap (fmap f) qs

instance Foldable Q where
    foldMap f (QAtom a) = f a
    foldMap f (QList qs) = mconcat $ fmap (foldMap f) qs

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList []) = pure $ QList []
    sequenceA (QList (qfa:qfas)) = concatL <$> (sequenceA qfa) <*> (sequenceA (QList qfas))
        where
            concatL (QAtom a) (QList qas) = QList ((QAtom a):qas)

这就是我所拥有的，它可以编译，但我并不特别喜欢 concatL 函数，它没有根据类型覆盖所有模式。一旦我开始向 Q 添加一个新的值构造函数 QDict [(Q Atom, Q a)]，情况会变得更糟。

我是否正确建模了原始数据？我什至应该尝试使它可遍历吗？但是我认为 Traversable 是必要的，如果我需要将数据类型与 Maybe 或 Each 一起使用来对错误进行建模。

任何建议表示赞赏。

编辑：编辑 q 代码格式

Answer 1

编译器知道如何自动Traversable为您的类型派生实例。如果您这样做:set -ddump-deriv -dsuppress-all -XDeriveTraversable -XStandaloneDeriving，然后deriving instance Traversable Q，您可以看到“正确”的答案。如果您将这些知识应用到您的实例中，您会得到：

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList qfas) = fmap QList (traverse sequenceA qfas)

或者，如果您想避免traverse支持sequenceA：

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList qfas) = fmap QList (sequenceA (fmap sequenceA qfas))

关键是列表本身是Traversable，因此您可以调用sequenceA它们而无需将它们的片段重新包装成您自己的类型。

旁注，在您的Foldable实例中，不要链接mconcatand fmap，只需foldMap再次使用，因为列表Foldable也是：

instance Foldable Q where
    foldMap f (QAtom a) = f a
    foldMap f (QList qs) = foldMap (foldMap f) qs